Merge pull request #64552 from evanjs/feature/openrazer-2.3.1

openrazer: init at 2.6.0

3 files changed, 88 insertions, 0 deletions

diff --git a/pkgs/development/python-modules/openrazer/common.nix b/pkgs/development/python-modules/openrazer/common.nix
new file mode 100644
index 00000000000..eac2751ce3e
--- /dev/null
+++ b/pkgs/development/python-modules/openrazer/common.nix
@@ -0,0 +1,17 @@
+{ stdenv
+, fetchFromGitHub
+}: rec {
+  version = "2.6.0";
+  src = fetchFromGitHub {
+    owner = "openrazer";
+    repo = "openrazer";
+    rev = "v${version}";
+    sha256 = "1s5irs3avrlp891mxan3z8p55ias9rq26rqp2qrlcc6i4vl29di0";
+  };
+  meta = with stdenv.lib; {
+    homepage = https://openrazer.github.io/;
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ roelvandijk ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/development/python-modules/openrazer/daemon.nix b/pkgs/development/python-modules/openrazer/daemon.nix
new file mode 100644
index 00000000000..6e3ab1e7833
--- /dev/null
+++ b/pkgs/development/python-modules/openrazer/daemon.nix
@@ -0,0 +1,45 @@
+{ buildPythonApplication
+, daemonize
+, dbus-python
+, fetchFromGitHub
+, fetchpatch
+, gobject-introspection
+, gtk3
+, makeWrapper
+, pygobject3
+, pyudev
+, setproctitle
+, stdenv
+, wrapGAppsHook
+}:
+
+let
+  common = import ./common.nix { inherit stdenv fetchFromGitHub; };
+in
+buildPythonApplication (common // rec {
+  pname = "openrazer_daemon";
+
+  sourceRoot = "source/daemon";
+
+  outputs = [ "out" "man" ];
+
+  nativeBuildInputs = [ makeWrapper wrapGAppsHook ];
+
+  propagatedBuildInputs = [
+    daemonize
+    dbus-python
+    gobject-introspection
+    gtk3
+    pygobject3
+    pyudev
+    setproctitle
+  ];
+
+  postBuild = ''
+    DESTDIR="$out" PREFIX="" make install manpages
+  '';
+
+  meta = common.meta // {
+    description = "An entirely open source user-space daemon that allows you to manage your Razer peripherals on GNU/Linux";
+  };
+})
diff --git a/pkgs/development/python-modules/openrazer/pylib.nix b/pkgs/development/python-modules/openrazer/pylib.nix
new file mode 100644
index 00000000000..2f9ff467b2d
--- /dev/null
+++ b/pkgs/development/python-modules/openrazer/pylib.nix
@@ -0,0 +1,26 @@
+{ buildPythonPackage
+, dbus-python
+, fetchFromGitHub
+, numpy
+, stdenv
+, openrazer-daemon
+}:
+
+let
+  common = import ./common.nix { inherit stdenv fetchFromGitHub; };
+in
+buildPythonPackage (common // rec {
+  pname = "openrazer";
+
+  sourceRoot = "source/pylib";
+
+  propagatedBuildInputs = [
+    dbus-python
+    numpy
+    openrazer-daemon
+  ];
+
+  meta = common.meta // {
+    description = "An entirely open source Python library that allows you to manage your Razer peripherals on GNU/Linux";
+  };
+})