Merge branch 'nixpkgs-update' into master

1 files changed, 51 insertions, 0 deletions

diff --git a/pkgs/development/python-modules/pyvex/default.nix b/pkgs/development/python-modules/pyvex/default.nix
new file mode 100644
index 00000000000..a6c2b1d381b
--- /dev/null
+++ b/pkgs/development/python-modules/pyvex/default.nix
@@ -0,0 +1,51 @@
+{ lib
+, stdenv
+, archinfo
+, bitstring
+, buildPythonPackage
+, cffi
+, fetchPypi
+, future
+, pycparser
+}:
+
+buildPythonPackage rec {
+  pname = "pyvex";
+  version = "9.0.9166";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0h7jw7blr4bal7pw711cxmwm4jjypchshc8ks04z2lyziy83ywja";
+  };
+
+  postPatch = lib.optionalString stdenv.isDarwin ''
+    substituteInPlace vex/Makefile-gcc --replace '/usr/bin/ar' 'ar'
+  '';
+
+  propagatedBuildInputs = [
+    archinfo
+    bitstring
+    cffi
+    future
+    pycparser
+  ];
+
+  preBuild = ''
+    export CC=${stdenv.cc.targetPrefix}cc
+    substituteInPlace pyvex_c/Makefile --replace 'AR=ar' 'AR=${stdenv.cc.targetPrefix}ar'
+  '';
+
+  # No tests are available on PyPI, GitHub release has tests
+  # Switch to GitHub release after all angr parts are present
+  doCheck = false;
+  pythonImportsCheck = [ "pyvex" ];
+
+  meta = with lib; {
+    description = "Python interface to libVEX and VEX IR";
+    homepage = "https://github.com/angr/pyvex";
+    license = with licenses; [ bsd2 gpl3Plus lgpl3Plus ];
+    maintainers = with maintainers; [ fab ];
+    # ERROR: pyvex-X-py3-none-manylinux1_aarch64.whl is not a supported wheel on this platform.
+    broken = stdenv.isAarch64;
+  };
+}