Last good Nixpkgs for Weston+nouveau? archive

I came this commit hash to terwiz[m] on IRC, who is trying to figure out
what the last version of Spectrum that worked on their NUC with Nvidia
graphics is.

1 files changed, 67 insertions, 0 deletions

diff --git a/pkgs/development/python-modules/limnoria/default.nix b/pkgs/development/python-modules/limnoria/default.nix
new file mode 100644
index 00000000000..27550c30dbf
--- /dev/null
+++ b/pkgs/development/python-modules/limnoria/default.nix
@@ -0,0 +1,67 @@
+{ lib
+, buildPythonPackage
+, chardet
+, cryptography
+, feedparser
+, fetchPypi
+, mock
+, pysocks
+, pytestCheckHook
+, python-dateutil
+, python-gnupg
+, pythonOlder
+, pytz
+}:
+
+buildPythonPackage rec {
+  pname = "limnoria";
+  version = "2022.3.17";
+  format = "setuptools";
+
+  disabled = pythonOlder "3.6";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-sSZFbEDlkc+F0PIwvseVEBoQQZVTFypW2nvLmPDD4u0=";
+  };
+
+  propagatedBuildInputs = [
+    chardet
+    cryptography
+    feedparser
+    mock
+    pysocks
+    python-dateutil
+    python-gnupg
+  ] ++ lib.optionals (pythonOlder "3.9") [
+    pytz
+  ];
+
+  checkInputs = [
+    pytestCheckHook
+  ];
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace "version=version" 'version="${version}"'
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+    export PATH="$PATH:$out/bin";
+    supybot-test test -v --no-network
+    runHook postCheck
+  '';
+
+  pythonImportsCheck = [
+    # Uses the same names as Supybot
+    "supybot"
+  ];
+
+  meta = with lib; {
+    description = "A modified version of Supybot, an IRC bot";
+    homepage = "https://github.com/ProgVal/Limnoria";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ goibhniu ];
+  };
+}