x265: 1.5 -> 1.6

+ Removed unused x265-hg package
+ Fix missing optionals
+ Fix high bit-depth to allow for all 64bit platforms

1 files changed, 55 insertions, 6 deletions

diff --git a/pkgs/development/libraries/x265/default.nix b/pkgs/development/libraries/x265/default.nix
index 30fbdcd1e8d..a2af56cbca6 100644
--- a/pkgs/development/libraries/x265/default.nix
+++ b/pkgs/development/libraries/x265/default.nix
@@ -1,7 +1,56 @@
-{ callPackage, ... } @ args:
+{ stdenv, fetchurl, cmake, yasm
+, debugSupport ? false # Run-time sanity checks (debugging)
+, highbitdepthSupport ? false # false=8bits per channel, true=10/12bits per channel
+, werrorSupport ? false # Warnings as errors
+, ppaSupport ? false # PPA profiling instrumentation
+, vtuneSupport ? false # Vtune profiling instrumentation
+, custatsSupport ? false # Internal profiling of encoder work
+, cliSupport ? true # Build standalone CLI application
+, unittestsSupport ? false # Unit tests
+}:
 
-callPackage ./generic.nix (args // {
-  version = "1.5";
-  rev = "9f0324125f53a12f766f6ed6f98f16e2f42337f4";
-  sha256 = "1nyim0l975faj7926s4wba8yvjy4rvx005zb7krv0gb5p84nzgi7";
-})
\ No newline at end of file
+let
+  mkFlag = optSet: flag: if optSet then "-D${flag}=ON" else "-D${flag}=OFF";
+  inherit (stdenv) is64bit;
+in
+
+stdenv.mkDerivation rec {
+  name = "x265-${version}";
+  version = "1.6";
+
+  src = fetchurl {
+    url = "https://github.com/videolan/x265/archive/${version}.tar.gz";
+    sha256 = "17c1phwmgcvvh9bakh1249rj2js77nr7y9igg34i3f8hsrdc4x0w";
+  };
+
+  patchPhase = ''
+    sed -i 's/unknown/${version}/g' source/cmake/version.cmake
+  '';
+
+  cmakeFlags = [
+    (mkFlag debugSupport "CHECKED_BUILD")
+    "-DSTATIC_LINK_CRT=OFF"
+    (mkFlag (highbitdepthSupport && is64bit) "HIGH_BIT_DEPTH")
+    (mkFlag werrorSupport "WARNINGS_AS_ERRORS")
+    (mkFlag ppaSupport "ENABLE_PPA")
+    (mkFlag vtuneSupport "ENABLE_VTUNE")
+    (mkFlag custatsSupport "DETAILED_CU_STATS")
+    "-DENABLE_SHARED=ON"
+    (mkFlag cliSupport "ENABLE_CLI")
+    (mkFlag unittestsSupport "ENABLE_TESTS")
+  ];
+
+  preConfigure = ''
+    cd source
+  '';
+
+  nativeBuildInputs = [ cmake yasm ];
+
+  meta = with stdenv.lib; {
+    description = "Library for encoding h.265/HEVC video streams";
+    homepage    = http://x265.org;
+    license     = licenses.gpl2;
+    maintainers = with maintainers; [ codyopel ];
+    platforms   = platforms.all;
+  };
+}