Adding wxWidgets 3.0.0

1 files changed, 58 insertions, 0 deletions

diff --git a/pkgs/development/libraries/wxGTK-3.0/default.nix b/pkgs/development/libraries/wxGTK-3.0/default.nix
new file mode 100644
index 00000000000..33f42854c2c
--- /dev/null
+++ b/pkgs/development/libraries/wxGTK-3.0/default.nix
@@ -0,0 +1,58 @@
+{ stdenv, fetchurl, pkgconfig, gtk, libXinerama, libSM, libXxf86vm, xf86vidmodeproto
+, gstreamer, gst_plugins_base, GConf, setfile
+, withMesa ? true, mesa ? null, compat24 ? false, compat26 ? true, unicode ? true,
+}:
+
+assert withMesa -> mesa != null;
+
+with stdenv.lib;
+
+let
+  version = "3.0.0";
+in
+stdenv.mkDerivation {
+  name = "wxwidgets-${version}";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/wxwindows/wxWidgets-${version}.tar.bz2";
+    sha256 = "11dz8pn1nm79i054l05rzyk4vqxw7v0x6j78pj6mvr5nphwhad7z";
+  };
+
+  buildInputs =
+    [ gtk libXinerama libSM libXxf86vm xf86vidmodeproto gstreamer
+      gst_plugins_base GConf ]
+    ++ optional withMesa mesa
+    ++ optional stdenv.isDarwin setfile;
+
+  nativeBuildInputs = [ pkgconfig ];
+
+  configureFlags =
+    [ "--enable-gtk2" "--disable-precomp-headers" "--enable-mediactrl"
+      (if compat24 then "--enable-compat24" else "--disable-compat24")
+      (if compat26 then "--enable-compat26" else "--disable-compat26") ]
+    ++ optional unicode "--enable-unicode"
+    ++ optional withMesa "--with-opengl"
+    ++ optionals stdenv.isDarwin
+      # allow building on 64-bit
+      [ "--with-cocoa" "--enable-universal-binaries" ];
+
+  SEARCH_LIB = optionalString withMesa "${mesa}/lib";
+
+  preConfigure = "
+    substituteInPlace configure --replace 'SEARCH_INCLUDE=' 'DUMMY_SEARCH_INCLUDE='
+    substituteInPlace configure --replace 'SEARCH_LIB=' 'DUMMY_SEARCH_LIB='
+    substituteInPlace configure --replace /usr /no-such-path
+  " + optionalString stdenv.isDarwin ''
+    substituteInPlace configure --replace \
+      'ac_cv_prog_SETFILE="/Developer/Tools/SetFile"' \
+      'ac_cv_prog_SETFILE="${setfile}/bin/SetFile"'
+  '';
+
+  postInstall = "
+    (cd $out/include && ln -s wx-*/* .)
+  ";
+
+  passthru = {inherit gtk compat24 compat26 unicode;};
+
+  enableParallelBuilding = true;
+}