gtkLibx3x update

svn path=/nixpkgs/trunk/; revision=29726

1 files changed, 55 insertions, 0 deletions

diff --git a/pkgs/development/libraries/gtk+/3.2.x.nix b/pkgs/development/libraries/gtk+/3.2.x.nix
new file mode 100644
index 00000000000..a72411d1636
--- /dev/null
+++ b/pkgs/development/libraries/gtk+/3.2.x.nix
@@ -0,0 +1,55 @@
+{ stdenv, fetchurl_gnome, pkgconfig, glib, atk, pango, cairo, perl, xlibs
+, gdk_pixbuf, xz
+, xineramaSupport ? true
+, cupsSupport ? true, cups ? null
+}:
+
+assert xineramaSupport -> xlibs.libXinerama != null;
+assert cupsSupport -> cups != null;
+
+stdenv.mkDerivation rec {
+  name = src.pkgname;
+
+  src = fetchurl_gnome {
+    project = "gtk+";
+    major = "3"; minor = "2"; patchlevel = "0"; extension = "xz";
+    sha256 = "0k6l5sw8njbnbapzm9v5jwlrrl7xv1b8c9lmqx97bzbapslw3qxw";
+  };
+
+  enableParallelBuilding = true;
+
+  buildNativeInputs = [ perl pkgconfig xz ];
+
+  propagatedBuildInputs =
+    [ xlibs.xlibs glib atk pango gdk_pixbuf cairo
+      xlibs.libXrandr xlibs.libXrender xlibs.libXcomposite xlibs.libXi
+    ]
+    ++ stdenv.lib.optional xineramaSupport xlibs.libXinerama
+    ++ stdenv.lib.optionals cupsSupport [ cups ];
+
+  configureFlags = "--with-xinput=yes";
+
+  postInstall = "rm -rf $out/share/gtk-doc";
+
+  meta = {
+    description = "A multi-platform toolkit for creating graphical user interfaces";
+
+    longDescription = ''
+      GTK+ is a highly usable, feature rich toolkit for creating
+      graphical user interfaces which boasts cross platform
+      compatibility and an easy to use API.  GTK+ it is written in C,
+      but has bindings to many other popular programming languages
+      such as C++, Python and C# among others.  GTK+ is licensed
+      under the GNU LGPL 2.1 allowing development of both free and
+      proprietary software with GTK+ without any license fees or
+      royalties.
+    '';
+
+    homepage = http://www.gtk.org/;
+
+    license = "LGPLv2+";
+
+    maintainers = with stdenv.lib.maintainers; [urkud raskin];
+    platforms = stdenv.lib.platforms.linux;
+  };
+}