font-awesome: 5.15.3 -> 6.1.1

1 files changed, 51 insertions, 0 deletions

diff --git a/pkgs/data/fonts/font-awesome/default.nix b/pkgs/data/fonts/font-awesome/default.nix
new file mode 100644
index 00000000000..3403660b1e8
--- /dev/null
+++ b/pkgs/data/fonts/font-awesome/default.nix
@@ -0,0 +1,51 @@
+{ lib, fetchFromGitHub }:
+let
+  font-awesome = { version, sha256, rev ? version }: fetchFromGitHub {
+    name = "font-awesome-${version}";
+
+
+    owner = "FortAwesome";
+    repo = "Font-Awesome";
+    inherit rev;
+
+    postFetch = ''
+      tar xf $downloadedFile --strip=1
+      install -m444 -Dt $out/share/fonts/opentype {fonts,otfs}/*.otf
+    '';
+
+    inherit sha256;
+
+    meta = with lib; {
+      description = "Font Awesome - OTF font";
+      longDescription = ''
+        Font Awesome gives you scalable vector icons that can instantly be customized.
+        This package includes only the OTF font. For full CSS etc. see the project website.
+      '';
+      homepage = "https://fontawesome.com/";
+      license = licenses.ofl;
+      platforms = platforms.all;
+      maintainers = with maintainers; [ abaldeau johnazoidberg ];
+    };
+  };
+in
+{
+  # Keeping version 4 and 5 because version 6 is incompatible for some icons. That
+  # means that projects which depend on it need to actively convert the
+  # symbols. See:
+  # https://github.com/greshake/i3status-rust/issues/130
+  # https://fontawesome.com/how-to-use/on-the-web/setup/upgrading-from-version-4
+  # https://fontawesome.com/v6/docs/web/setup/upgrade/
+  v4 = font-awesome {
+    version = "4.7.0";
+    rev = "v4.7.0";
+    sha256 = "1j8i32dq6rrlv3kf2hnq81iqks06kczaxjks7nw3zyq1231winm9";
+  };
+  v5 = font-awesome {
+    version = "5.15.3";
+    sha256 = "sha256-EDxk/yO3nMmtM/ytrAEgPYSBbep3rA3NrKkiqf3OsU0=";
+  };
+  v6 = font-awesome {
+    version = "6.1.1";
+    sha256 = "sha256-BjK1PJQFWtKDvfQ2Vh7BoOPqYucyvOG+2Pu/Kh+JpAA";
+  };
+}