sonobus: init at 1.6.2

Co-authored-by: tobiasBora <tobias.bora@gmail.com>

sonobus: add meta

sonobus: remove tree dependency (left from debug)

sonobus: rewrite comments

sonobus: remove platform

sonobus: apply suggestions from review

Co-authored-by: Nikolay Korotkiy <sikmir@disroot.org>
Co-authored-by: Matthias Thym <git@thym.at>

sonobus: mark darwin as broken

Co-authored-by: Weijia Wang <9713184+wegank@users.noreply.github.com>

sonobus: apply suggestions from code review

Co-authored-by: Lily Foster <lily@lily.flowers>

sonobus: remove opusTools

sonobus: 1.6.2

sonobus: change to autoPatchelfHook

Co-authored-by: Lily Foster <lily@lily.flowers>

1 files changed, 83 insertions, 0 deletions

diff --git a/pkgs/applications/audio/sonobus/default.nix b/pkgs/applications/audio/sonobus/default.nix
new file mode 100644
index 00000000000..da82fcc5a86
--- /dev/null
+++ b/pkgs/applications/audio/sonobus/default.nix
@@ -0,0 +1,83 @@
+{ lib
+, pkg-config
+, stdenv
+, fetchFromGitHub
+, autoPatchelfHook
+, alsa-lib
+, cmake
+, freetype
+, libGL
+, libX11
+, libXcursor
+, libXext
+, libXinerama
+, libXrandr
+, libjack2
+, libopus
+, curl
+, gtk3
+, webkitgtk
+}:
+
+stdenv.mkDerivation rec {
+  pname = "sonobus";
+  version = "1.6.2";
+
+  src = fetchFromGitHub {
+    owner = "sonosaurus";
+    repo = "sonobus";
+    rev = version;
+    sha256 = "sha256-/Pb+PYmoCYA6Qcy/tR1Ejyt+rZ3pfJeWV4j7bQWYE58=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    alsa-lib
+    freetype
+    libjack2
+    libopus
+    curl
+    gtk3
+    webkitgtk
+  ];
+
+  runtimeDependencies = [
+    libGL
+    libX11
+    libXcursor
+    libXext
+    libXinerama
+    libXrandr
+  ];
+
+  postPatch = lib.optionalString (stdenv.isLinux) ''
+    # needs special setup on Linux, dunno if it can work on Darwin
+    # https://github.com/NixOS/nixpkgs/issues/19098
+    # Also, I get issues with linking without that, not sure why
+    sed -i -e '/juce::juce_recommended_lto_flags/d' CMakeLists.txt
+    patchShebangs linux/install.sh
+  '';
+
+  # The program does not provide any CMake install instructions
+  installPhase = lib.optionalString (stdenv.isLinux) ''
+    runHook preInstall
+    cd ../linux
+    ./install.sh "$out"
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "High-quality network audio streaming";
+    homepage = "https://sonobus.net/";
+    license = with licenses; [ gpl3Plus ];
+    maintainers = with maintainers; [ PowerUser64 ];
+    platforms = platforms.unix;
+    broken = stdenv.isDarwin;
+  };
+}