qimgv: init at 0.8.9

A few notes:

* I only run Linux, so that is what I set `meta.platforms` to.
* Video support is broken in both Nix and Arch builds.

1 files changed, 49 insertions, 0 deletions

diff --git a/pkgs/applications/graphics/qimgv/default.nix b/pkgs/applications/graphics/qimgv/default.nix
new file mode 100644
index 00000000000..6402868b922
--- /dev/null
+++ b/pkgs/applications/graphics/qimgv/default.nix
@@ -0,0 +1,49 @@
+{ mkDerivation, fetchFromGitHub, lib
+, pkgconfig, cmake
+, exiv2, qtbase, qtimageformats, qtsvg
+}:
+
+mkDerivation rec {
+  pname = "qimgv";
+  version = "0.8.9";
+
+  src = fetchFromGitHub {
+    owner = "easymodo";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "0cmya06j466v0pirhxbzbj1vbz0346y7rbc1gbv4n9xcp6c6bln6";
+  };
+
+  cmakeFlags = [
+    # Video support appears to be broken; the following gets printed upon
+    # attempting to view an mp4, webm, or mkv (and probably all video formats):
+    #
+    #   [VideoPlayerInitProxy] Error - could not load player library
+    #   "qimgv_player_mpv"
+    #
+    # GIFs are unaffected. If this ever gets addressed, all that is necessary is
+    # to add `mpv` to the arguments list and to `buildInputs`, and to remove
+    # `cmakeFlags`.
+    "-DVIDEO_SUPPORT=OFF"
+  ];
+
+  nativeBuildInputs = [
+    pkgconfig
+    cmake
+  ];
+
+  buildInputs = [
+    exiv2
+    qtbase
+    qtimageformats
+    qtsvg
+  ];
+
+  meta = with lib; {
+    description = "Qt5 image viewer with optional video support";
+    homepage = "https://github.com/easymodo/qimgv";
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ cole-h ];
+  };
+}