textadept: moved to subdir for 10th version

2 files changed, 93 insertions, 0 deletions

diff --git a/pkgs/applications/editors/textadept/10/default.nix b/pkgs/applications/editors/textadept/10/default.nix
new file mode 100644
index 00000000000..0456d013bbb
--- /dev/null
+++ b/pkgs/applications/editors/textadept/10/default.nix
@@ -0,0 +1,51 @@
+{ lib, stdenv, fetchhg, fetchurl, gtk2, glib, pkgconfig, unzip, ncurses, zip }:
+
+stdenv.mkDerivation rec {
+  version = "10.8";
+  pname = "textadept";
+
+  nativeBuildInputs = [ pkgconfig ];
+  buildInputs = [
+    gtk2 ncurses glib unzip zip
+  ];
+
+  src = fetchhg {
+    url = "http://foicica.com/hg/textadept";
+    rev = "textadept_${version}";
+    sha256 = "sha256-dEZSx2tuHTWYhk9q5iGlrWTAvDvKaM8HaHwXcFcv33s=";
+  };
+
+  preConfigure =
+    lib.concatStringsSep "\n" (lib.mapAttrsToList (name: params:
+      "ln -s ${fetchurl params} $PWD/src/${name}"
+    ) (import ./deps.nix)) + ''
+
+    cd src
+    make deps
+  '';
+
+  postBuild = ''
+    make curses
+  '';
+
+  preInstall = ''
+    mkdir -p $out/share/applications
+    mkdir -p $out/share/pixmaps
+  '';
+
+  postInstall = ''
+    make curses install PREFIX=$out MAKECMDGOALS=curses
+  '';
+
+  makeFlags = [
+    "PREFIX=$(out) WGET=true PIXMAPS_DIR=$(out)/share/pixmaps"
+  ];
+
+  meta = with stdenv.lib; {
+    description = "An extensible text editor based on Scintilla with Lua scripting";
+    homepage = "http://foicica.com/textadept";
+    license = licenses.mit;
+    maintainers = with maintainers; [ raskin mirrexagon ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/applications/editors/textadept/10/deps.nix b/pkgs/applications/editors/textadept/10/deps.nix
new file mode 100644
index 00000000000..3ab778dddb2
--- /dev/null
+++ b/pkgs/applications/editors/textadept/10/deps.nix
@@ -0,0 +1,42 @@
+{
+    "99fa62b828ee.zip" = {
+      url = "http://foicica.com/hg/scintilla/archive/99fa62b828ee.zip";
+      sha256 = "sha256-QO4iGhx72CfB1/0Pp/Qab92qm98VZn/EkrHZGndoHVc=";
+    };
+    "lua-5.3.5.tar.gz" = {
+      url = "http://www.lua.org/ftp/lua-5.3.5.tar.gz";
+      sha256 = "1b2qn2rv96nmbm6zab4l877bd4zq7wpwm8drwjiy2ih4jqzysbhc";
+    };
+    "lpeg-1.0.2.tar.gz" = {
+      url = "http://www.inf.puc-rio.br/~roberto/lpeg/lpeg-1.0.2.tar.gz";
+      sha256 = "sha256-SNZldgUbbHg4j6rQm3BJMJMmRYj80PJY3aqxzdShX/4=";
+    };
+    "v1_7_0_2.zip" = {
+      url = "https://github.com/keplerproject/luafilesystem/archive/v1_7_0_2.zip";
+      sha256 = "sha256-kXSriR8dOStCpYeyr7c3+VZez4qGDS5aK/9FeFj1hHg=";
+    };
+    "db67f8a489e8.zip" = {
+      url = "http://foicica.com/hg/gtdialog/archive/db67f8a489e8.zip";
+      sha256 = "sha256-UIvjbDrg3jyz7t2tm4y1zzH/TG6Kqaz3LE5y2U6OHuM=";
+    };
+    "cdk-5.0-20150928.tgz" = {
+      url = "http://invisible-mirror.net/archives/cdk/cdk-5.0-20150928.tgz";
+      sha256 = "0j74l874y33i26y5kjg3pf1vswyjif8k93pqhi0iqykpbxfsg382";
+    };
+    "libtermkey-0.20.tar.gz" = {
+      url = "http://www.leonerd.org.uk/code/libtermkey/libtermkey-0.20.tar.gz";
+      sha256 = "1xfj6lchhfljmbcl6dz8dpakppyy13nbl4ykxiv5x4dr9b4qf3bc";
+    };
+    "pdcurs36.zip" = {
+      url = "http://prdownloads.sourceforge.net/pdcurses/pdcurs36.zip";
+      sha256 = "0y91zpygrxms7d1l5ksrz42bkvq8jd2xqlj5j7wgyxcl58chcw9b";
+    };
+    "bombay.zip" = {
+      url = "http://foicica.com/hg/bombay/archive/b25520cc76bb.zip";
+      sha256 = "07spq7jmkfyq20gv67yffara3ln3ns2xi0k02m2mxdms3xm1q36h";
+    };
+    "cloc-1.60.pl" = {
+      url = "http://prdownloads.sourceforge.net/cloc/cloc-1.60.pl";
+      sha256 = "0p504bi19va3dh274v7lb7giqrydwa5yyry60f7jpz84y6z71a2a";
+    };
+}