kakounePlugins: add buildKakounePlugin helper

Same as buildVimPlugin but for Kakoune

2 files changed, 37 insertions, 0 deletions

diff --git a/pkgs/applications/editors/kakoune/plugins/build-kakoune-plugin.nix b/pkgs/applications/editors/kakoune/plugins/build-kakoune-plugin.nix
new file mode 100644
index 00000000000..f35a175312c
--- /dev/null
+++ b/pkgs/applications/editors/kakoune/plugins/build-kakoune-plugin.nix
@@ -0,0 +1,33 @@
+{ lib, stdenv, rtpPath ? "share/kak/autoload/plugins" }:
+rec {
+  buildKakounePlugin = attrs@{
+    name ? "${attrs.pname}-${attrs.version}",
+    namePrefix ? "kakplugin-",
+    src,
+    unpackPhase ? "",
+    configurePhase ? "",
+    buildPhase ? "",
+    preInstall ? "",
+    postInstall ? "",
+    path ? lib.getName name,
+    ...
+  }:
+    stdenv.mkDerivation ((builtins.removeAttrs attrs [ "namePrefix" "path" ]) // {
+      name = namePrefix + name;
+
+      installPhase = ''
+        runHook preInstall
+
+        target=$out/${rtpPath}/${path}
+        mkdir -p $out/${rtpPath}
+        cp -r . $target
+
+        runHook postInstall
+      '';
+    });
+
+  buildKakounePluginFrom2Nix = attrs: buildKakounePlugin ({
+    buildPhase = ":";
+    configurePhase = ":";
+  } // attrs);
+}
diff --git a/pkgs/applications/editors/kakoune/plugins/kakoune-utils.nix b/pkgs/applications/editors/kakoune/plugins/kakoune-utils.nix
new file mode 100644
index 00000000000..11a1cc130d6
--- /dev/null
+++ b/pkgs/applications/editors/kakoune/plugins/kakoune-utils.nix
@@ -0,0 +1,4 @@
+{ lib, stdenv }:
+{
+  inherit (import ./build-kakoune-plugin.nix { inherit lib stdenv; }) buildKakounePlugin buildKakounePluginFrom2Nix;
+}