tree: rename altcoins to blockchains

Signed-off-by: William Casarin <jb55@jb55.com>

1 files changed, 47 insertions, 0 deletions

diff --git a/pkgs/applications/blockchains/monero/default.nix b/pkgs/applications/blockchains/monero/default.nix
new file mode 100644
index 00000000000..f351c9fa504
--- /dev/null
+++ b/pkgs/applications/blockchains/monero/default.nix
@@ -0,0 +1,47 @@
+{ stdenv, fetchgit
+, cmake, pkgconfig, git
+, boost, miniupnpc, openssl, unbound, cppzmq
+, zeromq, pcsclite, readline, libsodium, hidapi
+, python3Packages
+, CoreData, IOKit, PCSC
+}:
+
+assert stdenv.isDarwin -> IOKit != null;
+
+with stdenv.lib;
+
+stdenv.mkDerivation rec {
+  name    = "monero-${version}";
+  version = "0.14.1.0";
+
+  src = fetchgit {
+    url    = "https://github.com/monero-project/monero.git";
+    rev    = "v${version}";
+    sha256 = "1asa197fad81jfv12qgaa7y7pdr1r1pda96m9pvivkh4v30cx0nh";
+  };
+
+  nativeBuildInputs = [ cmake pkgconfig git ];
+
+  buildInputs = [
+    boost miniupnpc openssl unbound
+    cppzmq zeromq pcsclite readline
+    libsodium hidapi
+    python3Packages.protobuf
+  ] ++ optionals stdenv.isDarwin [ IOKit CoreData PCSC ];
+
+  cmakeFlags = [
+    "-DCMAKE_BUILD_TYPE=Release"
+    "-DBUILD_GUI_DEPS=ON"
+    "-DReadline_ROOT_DIR=${readline.dev}"
+  ] ++ optional stdenv.isDarwin "-DBoost_USE_MULTITHREADED=OFF";
+
+  hardeningDisable = [ "fortify" ];
+
+  meta = {
+    description = "Private, secure, untraceable currency";
+    homepage    = https://getmonero.org/;
+    license     = licenses.bsd3;
+    platforms   = platforms.all;
+    maintainers = with maintainers; [ ehmry rnhmjoj ];
+  };
+}