Last good Nixpkgs for Weston+nouveau? archive

I came this commit hash to terwiz[m] on IRC, who is trying to figure out
what the last version of Spectrum that worked on their NUC with Nvidia
graphics is.

1 files changed, 95 insertions, 0 deletions

diff --git a/pkgs/applications/blockchains/chia/default.nix b/pkgs/applications/blockchains/chia/default.nix
new file mode 100644
index 00000000000..e8527559c3a
--- /dev/null
+++ b/pkgs/applications/blockchains/chia/default.nix
@@ -0,0 +1,95 @@
+{ lib
+, cacert
+, fetchFromGitHub
+, python3Packages
+}:
+
+let chia = python3Packages.buildPythonApplication rec {
+  pname = "chia";
+  version = "1.3.1";
+
+  src = fetchFromGitHub {
+    owner = "Chia-Network";
+    repo = "chia-blockchain";
+    rev = version;
+    fetchSubmodules = true;
+    hash = "sha256-nH6rCzIQu5oWsdEHa+UkvbWeUGjrtpEKVEcLmSoor5k=";
+  };
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace "==" ">="
+
+    cp ${cacert}/etc/ssl/certs/ca-bundle.crt mozilla-ca/cacert.pem
+  '';
+
+  nativeBuildInputs = [
+    python3Packages.setuptools-scm
+  ];
+
+  # give a hint to setuptools-scm on package version
+  SETUPTOOLS_SCM_PRETEND_VERSION = "v${version}";
+
+  propagatedBuildInputs = with python3Packages; [
+    aiofiles
+    aiohttp
+    aiosqlite
+    bitstring
+    blspy
+    chiapos
+    chiavdf
+    chiabip158
+    click
+    clvm
+    clvm-rs
+    clvm-tools
+    colorama
+    colorlog
+    concurrent-log-handler
+    cryptography
+    dnslib
+    dnspythonchia
+    fasteners
+    filelock
+    keyrings-cryptfile
+    pyyaml
+    setproctitle
+    setuptools # needs pkg_resources at runtime
+    sortedcontainers
+    watchdog
+    websockets
+    zstd
+  ];
+
+  checkInputs = with python3Packages; [
+    pytestCheckHook
+  ];
+
+  # Testsuite is expensive and non-deterministic, so it is available in
+  # passthru.tests instead.
+  doCheck = false;
+
+  disabledTests = [
+    "test_spend_through_n"
+    "test_spend_zero_coin"
+    "test_default_cached_master_passphrase"
+    "test_using_legacy_keyring"
+  ];
+
+  preCheck = ''
+    export HOME=`mktemp -d`
+  '';
+
+  passthru.tests = {
+    chiaWithTests = chia.overrideAttrs (_: { doCheck = true; });
+  };
+
+  meta = with lib; {
+    homepage = "https://www.chia.net/";
+    description = "Chia is a modern cryptocurrency built from scratch, designed to be efficient, decentralized, and secure.";
+    license = with licenses; [ asl20 ];
+    maintainers = teams.chia.members;
+    platforms = platforms.all;
+  };
+};
+in chia