blob: 81d56fcf0340d22edf78b18131746d4852436299 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
{ lib
, rustPlatform
, fetchFromGitHub
, nix-update-script
, testers
, sonic-server
}:
rustPlatform.buildRustPackage rec {
pname = "sonic-server";
version = "1.4.3";
src = fetchFromGitHub {
owner = "valeriansaliou";
repo = "sonic";
rev = "refs/tags/v${version}";
hash = "sha256-V97K4KS46DXje4qKA11O9NEm0s13aTUnM+XW8lGc6fo=";
};
cargoHash = "sha256-vWAFWoscV0swwrBQoa3glKXMRgdGYa+QrPprlVCP1QM=";
# Found argument '--test-threads' which wasn't expected, or isn't valid in this context
doCheck = false;
nativeBuildInputs = [
rustPlatform.bindgenHook
];
postPatch = ''
substituteInPlace src/main.rs --replace "./config.cfg" "$out/etc/sonic/config.cfg"
'';
postInstall = ''
install -Dm444 -t $out/etc/sonic config.cfg
install -Dm444 -t $out/lib/systemd/system debian/sonic.service
substituteInPlace \
$out/lib/systemd/system/sonic.service \
--replace /usr/bin/sonic $out/bin/sonic \
--replace /etc/sonic.cfg $out/etc/sonic/config.cfg
'';
passthru = {
tests = {
version = testers.testVersion {
command = "sonic --version";
package = sonic-server;
};
};
updateScript = nix-update-script { };
};
meta = with lib; {
description = "Fast, lightweight and schema-less search backend";
homepage = "https://github.com/valeriansaliou/sonic";
changelog = "https://github.com/valeriansaliou/sonic/releases/tag/v${version}";
license = licenses.mpl20;
platforms = platforms.unix;
mainProgram = "sonic";
maintainers = with maintainers; [ pleshevskiy anthonyroussel ];
};
}
|