pkgs/development/tools/parsing/flex/2.6.1.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

{ lib, stdenv, fetchurl, bison, m4 }:

stdenv.mkDerivation {
  name = "flex-2.6.1";

  src = fetchurl {
    url = "https://github.com/westes/flex/releases/download/v2.6.1/flex-2.6.1.tar.gz";
    sha256 = "0fy14c35yz2m1n1m4f02by3501fn0cca37zn7jp8lpp4b3kgjhrw";
  };

  postPatch = ''
    patchShebangs tests
  '' + lib.optionalString (stdenv.hostPlatform != stdenv.buildPlatform) ''
    substituteInPlace Makefile.in --replace "tests" " ";
  '';

  buildInputs = [ bison ];

  propagatedBuildInputs = [ m4 ];

  preConfigure = lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
    "ac_cv_func_malloc_0_nonnull=yes"
    "ac_cv_func_realloc_0_nonnull=yes"
  ];

  postConfigure = lib.optionalString (stdenv.isDarwin || stdenv.isCygwin) ''
    sed -i Makefile -e 's/-no-undefined//;'
  '';

  meta = with lib; {
    homepage = "https://github.com/westes/flex";
    description = "A fast lexical analyser generator";
    license = licenses.bsd2;
    platforms = platforms.unix;
  };
}