blob: 546bb61bbc63080ef3e881fa34aab6b6e548e648 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
{ lib
, stdenv
, fetchFromSourcehut
, binutils-unwrapped
, harePackages
, makeWrapper
, qbe
, scdoc
, substituteAll
}:
let
inherit (harePackages) harec;
in
stdenv.mkDerivation (self: {
pname = "hare";
version = "unstable-2023-03-15";
src = fetchFromSourcehut {
owner = "~sircmpwn";
repo = "hare";
rev = "488771bc8cef15557a44815eb6f7808df40a09f7";
hash = "sha256-1cSXWD8jpW1VJZDTDOkIabczqbaDCOWsyaUSGtsKsUM=";
};
patches = [
./000-disable-failing-test-cases.diff
];
nativeBuildInputs = [
binutils-unwrapped
harec
makeWrapper
qbe
scdoc
];
buildInputs = [
binutils-unwrapped
harec
qbe
];
strictDeps = true;
configurePhase =
let
# https://harelang.org/platforms/
arch =
if stdenv.isx86_64 then "x86_64"
else if stdenv.isAarch64 then "aarch64"
else if stdenv.hostPlatform.isRiscV && stdenv.is64bit then "riscv64"
else "unsupported";
platform =
if stdenv.isLinux then "linux"
else if stdenv.isFreeBSD then "freebsd"
else "unsupported";
hareflags = "";
config-file = substituteAll {
src = ./config-template.mk;
inherit arch platform hareflags;
};
in
''
runHook preConfigure
export HARECACHE="$NIX_BUILD_TOP/.harecache"
export BINOUT="$NIX_BUILD_TOP/.bin"
cat ${config-file} > config.mk
runHook postConfigure
'';
makeFlags = [
"PREFIX=${placeholder "out"}"
];
doCheck = true;
postInstall =
let
binPath = lib.makeBinPath [
binutils-unwrapped
harec
qbe
];
in
''
wrapProgram $out/bin/hare --prefix PATH : ${binPath}
'';
setupHook = ./setup-hook.sh;
meta = {
homepage = "http://harelang.org/";
description =
"A systems programming language designed to be simple, stable, and robust";
license = lib.licenses.gpl3Only;
maintainers = [ lib.maintainers.AndersonTorres ];
inherit (harec.meta) platforms badPlatforms;
broken = stdenv.isAarch64; # still figuring how to set cross-compiling stuff
};
})
|