1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
{ lib
, stdenv
, fetchFromGitHub
, appstream-glib
, desktop-file-utils
, gio-sharp
, glib
, gstreamer
, gtk4
, libadwaita
, libxml2
, meson
, ninja
, pkg-config
, poppler
, python3
, rustPlatform
, shared-mime-info
, wrapGAppsHook4
}:
stdenv.mkDerivation rec {
pname = "rnote";
version = "0.4.0";
src = fetchFromGitHub {
owner = "flxzt";
repo = "rnote";
rev = "v${version}";
sha256 = "sha256-J7IW329rWFEoB+44762DAkWA8Hq4IVmXgc+QoDQaxV0=";
};
cargoDeps = rustPlatform.fetchCargoTarball {
inherit src;
name = "${pname}-${version}";
hash = "sha256-elXaikB/RemMxA4OXyZNQOgP1alImQMJHng5oX2j480=";
};
nativeBuildInputs = [
appstream-glib # For appstream-util
desktop-file-utils # For update-desktop-database
meson
ninja
pkg-config
python3 # For the postinstall script
rustPlatform.cargoSetupHook
rustPlatform.rust.cargo
rustPlatform.rust.rustc
shared-mime-info # For update-mime-database
wrapGAppsHook4
];
buildInputs = [
gio-sharp
glib
gstreamer
gtk4
libadwaita
libxml2
poppler
];
postPatch = ''
pushd build-aux
chmod +x meson_post_install.py
patchShebangs meson_post_install.py
substituteInPlace meson_post_install.py --replace "gtk-update-icon-cache" "gtk4-update-icon-cache"
popd
'';
meta = with lib; {
homepage = "https://github.com/flxzt/rnote";
description = "Simple drawing application to create handwritten notes";
license = licenses.gpl3Only;
maintainers = with maintainers; [ dotlambda yrd ];
platforms = platforms.linux;
};
}
|