nixos/modules/services/x11/desktop-managers/retroarch.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

{ config, lib, pkgs, ... }:

with lib;

let cfg = config.services.xserver.desktopManager.retroarch;

in {
  options.services.xserver.desktopManager.retroarch = {
    enable = mkEnableOption "RetroArch";

    package = mkOption {
      type = types.package;
      default = pkgs.retroarch;
      defaultText = literalExpression "pkgs.retroarch";
      example = literalExpression "pkgs.retroarch-full";
      description = lib.mdDoc "RetroArch package to use.";
    };

    extraArgs = mkOption {
      type = types.listOf types.str;
      default = [ ];
      example = [ "--verbose" "--host" ];
      description = lib.mdDoc "Extra arguments to pass to RetroArch.";
    };
  };

  config = mkIf cfg.enable {
    services.xserver.desktopManager.session = [{
      name = "RetroArch";
      start = ''
        ${cfg.package}/bin/retroarch -f ${escapeShellArgs cfg.extraArgs} &
        waitPID=$!
      '';
    }];

    environment.systemPackages = [ cfg.package ];
  };

  meta.maintainers = with maintainers; [ j0hax ];
}