pkgs/tools/networking/zs-wait4host/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

{ coreutils, fetchurl, fping, lib, stdenvNoCC }:

stdenvNoCC.mkDerivation rec {
  pname = "zs-wait4host";
  version = "0.3.2";

  src = fetchurl {
    url = "https://ytrizja.de/distfiles/${pname}-${version}.tar.gz";
    sha256 = "9F1264BDoGlRR7bWlRXhfyvxWio4ydShKmabUQEIz9I=";
  };

  postPatch = ''
    for i in zs-wait4host zs-wait4host-inf; do
      substituteInPlace "$i" \
        --replace '$(zs-guess-fping)' '${fping}/bin/fping' \
        --replace ' sleep ' ' ${coreutils}/bin/sleep ' \
        --replace '[ "$FPING" ] || exit 1' ""
    done
  '';

  installPhase = ''
    runHook preInstall
    install -D -t $out/bin zs-wait4host zs-wait4host-inf
    runHook postInstall
  '';

  meta = with lib; {
    description = "Wait for a host to come up/go down";
    homepage = "https://ytrizja.de/";
    license = licenses.gpl3Plus;
    maintainers = with maintainers; [ zseri ];
    platforms = platforms.all;
  };
}