pkgs/tools/graphics/transfig/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

{ stdenv, fetchurl, zlib, libjpeg, libpng, imake, gccmakedep }:

stdenv.mkDerivation {
  name = "transfig-3.2.4";
  src = fetchurl {
    url = "ftp://ftp.tex.ac.uk/pub/archive/graphics/transfig/transfig.3.2.4.tar.gz";
    sha256 = "0429snhp5acbz61pvblwlrwv8nxr6gf12p37f9xxwrkqv4ir7dd4";
  };

  nativeBuildInputs = [ imake gccmakedep ];
  buildInputs = [ zlib libjpeg libpng ];

  patches = [
    ./patch-fig2dev-dev-Imakefile
    ./patch-fig2dev-Imakefile
    ./patch-transfig-Imakefile
    ./patch-fig2dev-fig2dev.h
    ./patch-fig2dev-dev-gensvg.c
  ];

  patchPhase = ''
    runHook prePatch

    configureImakefiles() {
        local sedcmd=$1

        sed "$sedcmd" fig2dev/Imakefile > tmpsed
        cp tmpsed fig2dev/Imakefile

        sed "$sedcmd" fig2dev/dev/Imakefile > tmpsed
        cp tmpsed fig2dev/dev/Imakefile

        sed "$sedcmd" transfig/Imakefile > tmpsed
        cp tmpsed transfig/Imakefile
    }

    for i in $patches; do
        header "applying patch $i" 3
        patch -p0 < $i
        stopNest
    done

    configureImakefiles "s:__PREFIX_PNG:${libpng}:"
    configureImakefiles "s:__PREFIX:$out:"

    runHook postPatch
  '';

  makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];

  preInstall = ''
    mkdir -p $out
    mkdir -p $out/lib
  '';

  hardeningDisable = [ "format" ];

  meta = {
    platforms = stdenv.lib.platforms.unix;
  };
}