blob: 57ab854a33cbdf900c6568c52e8e5a9838c45169 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
{ stdenv, fetchFromGitHub, makeWrapper
, perl, pandoc, python2Packages, git
, par2cmdline ? null, par2Support ? true
}:
assert par2Support -> par2cmdline != null;
let version = "0.30.1"; in
with stdenv.lib;
stdenv.mkDerivation {
pname = "bup";
inherit version;
src = fetchFromGitHub {
repo = "bup";
owner = "bup";
rev = version;
sha256 = "0z9rpmmi6mbm48ynd6izr0f8l3cklfyar6gjy0c8z9zal1ac9r55";
};
buildInputs = [
git
(python2Packages.python.withPackages
(p: with p; [ setuptools tornado ]
++ stdenv.lib.optionals (!stdenv.isDarwin) [ pyxattr pylibacl fuse ]))
];
nativeBuildInputs = [ pandoc perl makeWrapper ];
postPatch = ''
patchShebangs .
substituteInPlace Makefile --replace "-Werror" ""
substituteInPlace Makefile --replace "./format-subst.pl" "${perl}/bin/perl ./format-subst.pl"
'' + optionalString par2Support ''
substituteInPlace cmd/fsck-cmd.py --replace "['par2'" "['${par2cmdline}/bin/par2'"
'';
dontAddPrefix = true;
makeFlags = [
"MANDIR=$(out)/share/man"
"DOCDIR=$(out)/share/doc/bup"
"BINDIR=$(out)/bin"
"LIBDIR=$(out)/lib/bup"
];
postInstall = ''
wrapProgram $out/bin/bup \
--prefix PATH : ${git}/bin
'';
meta = {
homepage = "https://github.com/bup/bup";
description = "Efficient file backup system based on the git packfile format";
license = licenses.gpl2Plus;
longDescription = ''
Highly efficient file backup system based on the git packfile format.
Capable of doing *fast* incremental backups of virtual machine images.
'';
platforms = platforms.linux ++ platforms.darwin;
maintainers = with maintainers; [ muflax ];
};
}
|