summary refs log tree commit diff
path: root/pkgs/os-specific/linux/device-tree/default.nix
blob: 13c609cdf7d93e7ce15fddda45d193535a996c1f (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
{ lib, stdenvNoCC, dtc, findutils }:

with lib; {
  applyOverlays = (base: overlays': stdenvNoCC.mkDerivation {
    name = "device-tree-overlays";
    nativeBuildInputs = [ dtc findutils ];
    buildCommand = let
      overlays = toList overlays';
    in ''
      mkdir -p $out
      cd ${base}
      find . -type f -name '*.dtb' -print0 \
        | xargs -0 cp -v --no-preserve=mode --target-directory $out --parents

      for dtb in $(find $out -type f -name '*.dtb'); do
        dtbCompat="$( fdtget -t s $dtb / compatible )"

        ${flip (concatMapStringsSep "\n") overlays (o: ''
        overlayCompat="$( fdtget -t s ${o.dtboFile} / compatible )"
        # overlayCompat in dtbCompat
        if [[ "$dtbCompat" =~ "$overlayCompat" ]]; then
          echo "Applying overlay ${o.name} to $( basename $dtb )"
          mv $dtb{,.in}
          fdtoverlay -o "$dtb" -i "$dtb.in" ${o.dtboFile};
          rm $dtb.in
        fi
        '')}

      done
    '';
  });
}