summary refs log tree commit diff
path: root/pkgs/os-specific/linux/chromium-os/modem-manager/default.nix
blob: c6a5a44b67e4c90e04e571bee0c9beadd931fca1 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
{ modemmanager, lib, fetchFromGitiles
, autoreconfHook, libtool, intltool, libxslt, dbus_glib, chromiumos-overlay
}:

modemmanager.overrideAttrs (
  { pname, nativeBuildInputs ? [], buildInputs ? [], postInstall ? "", meta ? {}
  , ... }:
  {
    pname = "${pname}-chromiumos-unstable";
    version = "2012-04-10";

    src = fetchFromGitiles {
      url = "https://chromium.googlesource.com/chromiumos/third_party/modemmanager";
      rev = "657324d1abfd446b0319e4c51bd30cf4967eccf4";
      sha256 = "12wlak8zx914zix4vv5a8sl0nyi58v7593h4gjchgv3i8ysgj9ah";
    };

    nativeBuildInputs = nativeBuildInputs ++ [ autoreconfHook libtool intltool libxslt ];
    buildInputs = buildInputs ++ [ dbus_glib ];

    preAutoreconf = ''
      intltoolize
    '';

    NIX_CFLAGS_COMPILE = [ "-Wno-error" ];

    meta = with lib; meta // {
      maintainers = with maintainers; [ qyliss ];
    };
  }
)