summary refs log tree commit diff
path: root/pkgs/os-specific/linux/chromium-os/crosvm/default.nix
blob: f8b6b13e69465be4a489b619dd5ef3c563362e0a (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
{ stdenv, lib, rustPlatform, fetchFromGitiles, upstreamInfo
, pkgconfig, minigbm, minijail, wayland, wayland-protocols, dtc, libusb1, libcap
, linux
}:

let
  arch = with stdenv.hostPlatform;
    if isAarch64 then "arm"
    else if isx86_64 then "x86_64"
    else throw "no seccomp policy files available for host platform";

  getSrc = path: fetchFromGitiles upstreamInfo.components.${path};
  srcs = lib.genAttrs [
    "src/aosp/external/minijail"
    "src/platform/crosvm"
    "src/platform2"
    "src/third_party/adhd"
    "src/third_party/rust-vmm/vhost"
  ] getSrc;
in

  rustPlatform.buildRustPackage rec {
    pname = "crosvm";
    inherit (upstreamInfo) version;

    unpackPhase = ''
      runHook preUnpack

      ${lib.concatStringsSep "\n" (lib.mapAttrsToList (path: src: ''
        mkdir -p ${dirOf path}
        pushd ${dirOf path}
        unpackFile ${src}
        popd
      '') srcs)}

      chmod -R u+w -- "$sourceRoot"

      runHook postUnpack
    '';

    sourceRoot = "src/platform/crosvm";

    patches = [
      ./default-seccomp-policy-dir.diff
      ./VIRTIO_NET_F_MAC.patch
    ];

    cargoSha256 = "1hw9r7vggvn8p0sy4k0i2ijpyk0yb11qww6s6d6wdfvrl1ksbapl";

    nativeBuildInputs = [ pkgconfig wayland ];

    buildInputs = [ dtc libcap libusb1 minigbm minijail wayland wayland-protocols ];

    postPatch = ''
      sed -i "s|/usr/share/policy/crosvm/|$out/share/policy/|g" \
             seccomp/*/*.policy
    '';

    preBuild = ''
      export DEFAULT_SECCOMP_POLICY_DIR=$out/share/policy
    '';

    postInstall = ''
      mkdir -p $out/share/policy/
      cp seccomp/${arch}/* $out/share/policy/
    '';

    CROSVM_CARGO_TEST_KERNEL_BINARY =
      lib.optionalString (stdenv.buildPlatform == stdenv.hostPlatform)
        "${linux}/${stdenv.hostPlatform.platform.kernelTarget}";

    passthru = {
      inherit srcs;
      src = srcs.${sourceRoot};
      updateScript = ../update.py;
    };

    meta = with lib; {
      description = "A secure virtual machine monitor for KVM";
      homepage = "https://chromium.googlesource.com/chromiumos/platform/crosvm/";
      maintainers = with maintainers; [ qyliss ];
      license = licenses.bsd3;
      platforms = [ "aarch64-linux" "x86_64-linux" ];
    };
  }