blob: 5eebcd4a38e7cf27d3c63a3feec07a33af55f6ab (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
{ stdenv, lib, fetchurl, alsaLib, libpulseaudio, undmg }:
let
bits = stdenv.lib.optionalString (stdenv.hostPlatform.system == "x86_64-linux") "64";
libPath = lib.makeLibraryPath [ stdenv.cc.cc alsaLib libpulseaudio ];
in
stdenv.mkDerivation rec {
pname = "fmod";
version = "4.44.64";
shortVersion = builtins.replaceStrings [ "." ] [ "" ] version;
src = fetchurl (if stdenv.isLinux then {
url = "https://zdoom.org/files/fmod/fmodapi${shortVersion}linux.tar.gz";
sha256 = "047hk92xapwwqj281f4zwl0ih821rrliya70gfj82sdfjh9lz8i1";
} else {
url = "https://zdoom.org/files/fmod/fmodapi${shortVersion}mac-installer.dmg";
sha256 = "1m1y4cpcwpkl8x31d3s68xzp107f343ma09w2437i2adn5y7m8ii";
});
nativeBuildInputs = [ undmg ];
dontStrip = true;
dontPatchELF = true;
dontBuild = true;
installPhase = lib.optionalString stdenv.isLinux ''
install -Dm755 api/lib/libfmodex${bits}-${version}.so $out/lib/libfmodex-${version}.so
ln -s libfmodex-${version}.so $out/lib/libfmodex.so
patchelf --set-rpath ${libPath} $out/lib/libfmodex.so
'' + lib.optionalString stdenv.isDarwin ''
install -D api/lib/libfmodex.dylib $out/lib/libfmodex.dylib
install -D api/lib/libfmodexL.dylib $out/lib/libfmodexL.dylib
'' + ''
cp -r api/inc $out/include
'';
meta = with stdenv.lib; {
description = "Programming library and toolkit for the creation and playback of interactive audio";
homepage = "http://www.fmod.org/";
license = licenses.unfreeRedistributable;
platforms = [ "x86_64-linux" "i686-linux" "x86_64-darwin" ];
maintainers = [ maintainers.lassulus ];
};
}
|