blob: e443ca7751eb54e099f49759f290176be1da52ab (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
{ lib, stdenv, buildPackages, fetchFromGitHub, autoreconfHook, coreutils, pkg-config, perl, python3Packages, libiconv, jansson }:
stdenv.mkDerivation rec {
pname = "universal-ctags";
version = "5.9.20210411.0";
src = fetchFromGitHub {
owner = "universal-ctags";
repo = "ctags";
rev = "p${version}";
sha256 = "0c031y0dl2b70pd0mqfbylplf8f27x11b0ch7ljka3rqav0zb1zr";
};
depsBuildBuild = [ buildPackages.stdenv.cc ];
nativeBuildInputs = [ autoreconfHook coreutils pkg-config python3Packages.docutils ];
buildInputs = [ jansson ] ++ lib.optional stdenv.isDarwin libiconv;
# to generate makefile.in
autoreconfPhase = ''
./autogen.sh
'';
configureFlags = [ "--enable-tmpdir=/tmp" ];
postPatch = ''
# Remove source of non-determinism
substituteInPlace main/options.c \
--replace "printf (\" Compiled: %s, %s\n\", __DATE__, __TIME__);" ""
substituteInPlace Tmain/utils.sh \
--replace /bin/echo ${coreutils}/bin/echo
'';
postConfigure = ''
sed -i 's|/usr/bin/env perl|${perl}/bin/perl|' misc/optlib2c
'';
doCheck = true;
checkFlags = [ "units" ];
meta = with lib; {
description = "A maintained ctags implementation";
homepage = "https://ctags.io/";
license = licenses.gpl2Plus;
platforms = platforms.unix;
# universal-ctags is preferred over emacs's ctags
priority = 1;
maintainers = [ maintainers.mimame ];
};
}
|