blob: 0e88e1c4926c1ba7801ed36cb6ab54d44e6d6789 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
{ lib, buildGoModule, fetchFromGitHub, installShellFiles }:
buildGoModule rec {
pname = "doctl";
version = "1.71.0";
vendorSha256 = null;
doCheck = false;
subPackages = [ "cmd/doctl" ];
ldflags = let t = "github.com/digitalocean/doctl"; in [
"-X ${t}.Major=${lib.versions.major version}"
"-X ${t}.Minor=${lib.versions.minor version}"
"-X ${t}.Patch=${lib.versions.patch version}"
"-X ${t}.Label=release"
];
nativeBuildInputs = [ installShellFiles ];
postInstall = ''
export HOME=$(mktemp -d) # attempts to write to /homeless-shelter
for shell in bash fish zsh; do
$out/bin/doctl completion $shell > doctl.$shell
installShellCompletion doctl.$shell
done
'';
src = fetchFromGitHub {
owner = "digitalocean";
repo = "doctl";
rev = "v${version}";
sha256 = "sha256-cj2+DmJyLa6kFkH9JflaR3yFFXBaVZHO6czJGLEH7L0=";
};
meta = with lib; {
description = "A command line tool for DigitalOcean services";
homepage = "https://github.com/digitalocean/doctl";
license = licenses.asl20;
maintainers = [ maintainers.siddharthist ];
};
}
|