blob: c0707a1cd9355467a280a71fa28871443deb60b2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
{ lib, stdenv, fetchFromGitLab, python3, ensureNewerSourcesForZipFilesHook
# optional list of extra waf tools, e.g. `[ "doxygen" "pytest" ]`
, withTools ? null
}:
let
wafToolsArg = with lib.strings;
optionalString (!isNull withTools) " --tools=\"${concatStringsSep "," withTools}\"";
in
stdenv.mkDerivation rec {
pname = "waf";
version = "2.0.23";
src = fetchFromGitLab {
owner = "ita1024";
repo = "waf";
rev = "${pname}-${version}";
sha256 = "sha256-AASjkXb3eCVjbuT0GOwhagoNHxG7/XP1Mj0i1U4j13Q=";
};
nativeBuildInputs = [ python3 ensureNewerSourcesForZipFilesHook ];
# waf bin has #!/usr/bin/env python
buildInputs = [ python3 ];
configurePhase = ''
python waf-light configure
'';
buildPhase = ''
python waf-light build${wafToolsArg}
'';
installPhase = ''
install -D waf $out/bin/waf
'';
strictDeps = true;
meta = with lib; {
description = "Meta build system";
homepage = "https://waf.io";
license = licenses.bsd3;
platforms = platforms.all;
maintainers = with maintainers; [ vrthra ];
};
}
|