pkgs/development/python-modules/pygmo/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

{ lib
, buildPythonPackage
, eigen
, nlopt
, ipopt
, boost
, pagmo2
, numpy
, cloudpickle
, ipyparallel
, numba
, python
}:

let
  propagatedBuildInputs = [ numpy cloudpickle ipyparallel numba ];

  pagmo2WithPython = pagmo2.overrideAttrs (oldAttrs: {
    cmakeFlags = oldAttrs.cmakeFlags ++ [
      "-DPAGMO_BUILD_PYGMO=yes"
      "-DPAGMO_BUILD_PAGMO=no"
      "-DPagmo_DIR=${pagmo2}"
    ];
    buildInputs = [ eigen nlopt ipopt boost pagmo2 ] ++ propagatedBuildInputs;
    postInstall = ''
      mv wheel $out
    '';
  });

in buildPythonPackage {
  pname = "pygmo";
  version = pagmo2WithPython.version;

  inherit propagatedBuildInputs;

  src = pagmo2WithPython;

  preBuild = ''
    mv ${python.sitePackages}/pygmo wheel
    cd wheel
  '';

  # dont do tests
  doCheck = false;

  meta = with lib; {
    description = "Parallel optimisation for Python";
    homepage = "https://esa.github.io/pagmo2/";
    license = licenses.gpl3Plus;
    maintainers = [ maintainers.costrouc ];
  };
}