blob: 97534b0ddd36c1d55063796b3d0c93f4381d5c22 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
{ stdenv, fetchurl, perl, nettools, java, polyml, proofgeneral }:
# nettools needed for hostname
let
dirname = "Isabelle2014";
theories = ["HOL" "FOL" "ZF"];
in
stdenv.mkDerivation {
name = "isabelle-2014";
inherit dirname theories;
src = if stdenv.isDarwin
then fetchurl {
url = http://isabelle.in.tum.de/website-Isabelle2014/dist/Isabelle2014_macos.tar.gz;
sha256 = "1aa3vz2nnkkyd4mlsqbs69jqfxlll5h0k5fj9m1j9wqiddqwvwcf";
}
else fetchurl {
url = http://isabelle.in.tum.de/website-Isabelle2014/dist/Isabelle2014_linux.tar.gz;
sha256 = "0z81pwwllavka4r57fx6yi9kbpbb9xbanp8dsjix49qpyj2a72jy";
};
buildInputs = [ perl polyml ]
++ stdenv.lib.optionals (!stdenv.isDarwin) [ nettools java ];
sourceRoot = dirname;
postPatch = ''
ENV=$(type -p env)
patchShebangs "."
substituteInPlace lib/Tools/env \
--replace /usr/bin/env $ENV
substituteInPlace lib/Tools/install \
--replace /usr/bin/env $ENV
substituteInPlace etc/settings \
--subst-var-by ML_HOME "${polyml}/bin" \
--subst-var-by PROOFGENERAL_HOME "${proofgeneral}/share/emacs/site-lisp/ProofGeneral"
substituteInPlace contrib/jdk/etc/settings \
--replace ISABELLE_JDK_HOME= '#ISABELLE_JDK_HOME='
substituteInPlace contrib/polyml-5.5.2-1/etc/settings \
--replace 'ML_HOME="$POLYML_HOME/$ML_PLATFORM"' \
"ML_HOME=\"${polyml}/bin\""
'';
buildPhase = ''
ISABELLE_JDK_HOME=${java} ./bin/isabelle build -s $theories
'';
installPhase = ''
mkdir -p $out/bin
mv $TMP/$dirname $out
cd $out/$dirname
bin/isabelle install $out/bin
'';
meta = {
description = "A generic proof assistant";
longDescription = ''
Isabelle is a generic proof assistant. It allows mathematical formulas
to be expressed in a formal language and provides tools for proving those
formulas in a logical calculus.
'';
homepage = http://isabelle.in.tum.de/;
license = "LGPL";
maintainers = [ stdenv.lib.maintainers.jwiegley ];
};
}
|