pkgs/applications/graphics/glimpse/wrapper.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

{ lib, symlinkJoin, glimpse, makeWrapper, glimpsePlugins, gnome, plugins ? null }:

let
  allPlugins = lib.filter (pkg: lib.isDerivation pkg && !pkg.meta.broken or false) (lib.attrValues glimpsePlugins);
  selectedPlugins = if plugins == null then allPlugins else plugins;
  extraArgs = map (x: x.wrapArgs or "") selectedPlugins;
  versionBranch = lib.versions.majorMinor glimpse.version;

in
symlinkJoin {
  name = "glimpse-with-plugins-${glimpse.version}";

  paths = [ glimpse ] ++ selectedPlugins;

  nativeBuildInputs = [ makeWrapper ];

  postBuild = ''
    for each in glimpse-${versionBranch} glimpse-console-${versionBranch}; do
      wrapProgram $out/bin/$each \
        --set GIMP2_PLUGINDIR "$out/lib/glimpse/2.0" \
        --set GIMP2_DATADIR "$out/share/glimpse/2.0" \
        --prefix GTK_PATH : "${gnome.gnome-themes-extra}/lib/gtk-2.0" \
        ${toString extraArgs}
    done

    for each in glimpse glimpse-console; do
      ln -sf "$each-${versionBranch}" $out/bin/$each
    done
  '';

  inherit (glimpse) meta;
}