summary refs log tree commit diff
path: root/nixos/modules/services/system/uptimed.nix
blob: 67a03876e19f9888b4f7d0910debb95421a2b987 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
{ config, lib, pkgs, ... }:

with lib;

let
  cfg = config.services.uptimed;
  stateDir = "/var/lib/uptimed";
in
{
  options = {
    services.uptimed = {
      enable = mkOption {
        type = types.bool;
        default = false;
        description = ''
          Enable <literal>uptimed</literal>, allowing you to track
          your highest uptimes.
        '';
      };
    };
  };

  config = mkIf cfg.enable {

    environment.systemPackages = [ pkgs.uptimed ];

    users.users.uptimed = {
      description = "Uptimed daemon user";
      home        = stateDir;
      uid         = config.ids.uids.uptimed;
      group       = "uptimed";
    };
    users.groups.uptimed = {};

    systemd.services.uptimed = {
      unitConfig.Documentation = "man:uptimed(8) man:uprecords(1)";
      description = "uptimed service";
      wantedBy    = [ "multi-user.target" ];

      serviceConfig = {
        Restart                 = "on-failure";
        User                    = "uptimed";
        Nice                    = 19;
        IOSchedulingClass       = "idle";
        PrivateTmp              = "yes";
        PrivateNetwork          = "yes";
        NoNewPrivileges         = "yes";
        StateDirectory          = [ "uptimed" ];
        InaccessibleDirectories = "/home";
        ExecStart               = "${pkgs.uptimed}/sbin/uptimed -f -p ${stateDir}/pid";
      };

      preStart = ''
        if ! test -f ${stateDir}/bootid ; then
          ${pkgs.uptimed}/sbin/uptimed -b
        fi
      '';
    };
  };
}