nixos/modules/services/monitoring/prometheus/exporters/py-air-control.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

{ config, lib, pkgs, options }:

with lib;

let
  cfg = config.services.prometheus.exporters.py-air-control;

  workingDir = "/var/lib/${cfg.stateDir}";

in
{
  port = 9896;
  extraOpts = {
    deviceHostname = mkOption {
      type = types.str;
      example = "192.168.1.123";
      description = ''
        The hostname of the air purification device from which to scrape the metrics.
      '';
    };
    protocol = mkOption {
      type = types.str;
      default = "http";
      description = ''
        The protocol to use when communicating with the air purification device.
        Available: [http, coap, plain_coap]
      '';
    };
    stateDir = mkOption {
      type = types.str;
      default = "prometheus-py-air-control-exporter";
      description = ''
        Directory below <literal>/var/lib</literal> to store runtime data.
        This directory will be created automatically using systemd's StateDirectory mechanism.
      '';
    };
  };
  serviceOpts = {
    serviceConfig = {
      DynamicUser = false;
      StateDirectory = cfg.stateDir;
      WorkingDirectory = workingDir;
      ExecStart = ''
        ${pkgs.python3Packages.py-air-control-exporter}/bin/py-air-control-exporter \
          --host ${cfg.deviceHostname} \
          --protocol ${cfg.protocol} \
          --listen-port ${toString cfg.port} \
          --listen-address ${cfg.listenAddress}
      '';
      Environment = [ "HOME=${workingDir}" ];
    };
  };
}