From 84c09b109e0bf185c68d90770f275930d02fac24 Mon Sep 17 00:00:00 2001
From: gnidorah <gnidorah@users.noreply.github.com>
Date: Thu, 3 Oct 2019 22:19:00 +0300
Subject: openxray: init at 510

---
 pkgs/games/openxray/default.nix | 52 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 pkgs/games/openxray/default.nix

(limited to 'pkgs/games/openxray/default.nix')

diff --git a/pkgs/games/openxray/default.nix b/pkgs/games/openxray/default.nix
new file mode 100644
index 00000000000..d8ff0dd8d9e
--- /dev/null
+++ b/pkgs/games/openxray/default.nix
@@ -0,0 +1,52 @@
+{ stdenv, fetchFromGitHub, cmake, glew, freeimage,  liblockfile
+, openal, cryptopp, libtheora, SDL2, lzo, libjpeg, libogg, tbb
+, pcre, makeWrapper }:
+
+stdenv.mkDerivation rec {
+  pname = "OpenXRay";
+  version = "510";
+
+  src = fetchFromGitHub {
+    owner = "OpenXRay";
+    repo = "xray-16";
+    rev = version;
+    sha256 = "0q142l6xvgnd6ycncqld69izxclynqrs73aq89pfy1r1nzhd60ay";
+    fetchSubmodules = true;
+  };
+
+  hardeningDisable = [ "format" ];
+  cmakeFlags = [ "-DCMAKE_INCLUDE_PATH=${cryptopp}/include/cryptopp" ];
+  installFlags = [ "DESTDIR=${placeholder "out"}" ];
+
+  buildInputs = [
+    glew freeimage liblockfile openal cryptopp libtheora SDL2 lzo
+    libjpeg libogg tbb pcre
+  ];
+  nativeBuildInputs = [ cmake makeWrapper ];
+
+  preConfigure = ''
+    substituteInPlace src/xrCore/xrCore.cpp \
+      --replace /usr/share $out/share
+  '';
+
+  postInstall = ''
+    mv $out/var/empty/* $out
+    install -Dm755 $out/games/xr_3da $out/bin/xr_3da
+    install -Dm644 $src/License.txt $out/share/licenses/openxray/License.txt
+    rm -r $out/var $out/games
+
+    # needed because of SDL_LoadObject library loading code
+    wrapProgram $out/bin/xr_3da \
+      --prefix LD_LIBRARY_PATH : $out/lib
+  '';
+
+  meta = with stdenv.lib; {
+    description = "X-Ray Engine 1.6 expansion. Original version was used in S.T.A.L.K.E.R.: Call of Pripyat";
+    homepage = src.meta.homepage;
+    license = licenses.unfree // {
+      url = https://github.com/OpenXRay/xray-16/blob/xd_dev/License.txt;
+    };
+    maintainers = [ maintainers.gnidorah ];
+    platforms = ["x86_64-linux" "i686-linux" ];
+  };
+}
-- 
cgit 1.4.1