From 41abde91ce6d77e3f93a1c4ac9b7e538d60d5d09 Mon Sep 17 00:00:00 2001
From: Nikolay Amiantov <ab@fmap.me>
Date: Sun, 25 Feb 2018 20:12:46 +0300
Subject: nccl: 1.2.4-1 -> 2.1.4

It's closed source now.
---
 .../libraries/science/math/nccl/default.nix        | 51 +++++++------------
 .../libraries/science/math/nccl/generic.nix        | 57 ++++++++++++++++++++++
 2 files changed, 74 insertions(+), 34 deletions(-)
 create mode 100644 pkgs/development/libraries/science/math/nccl/generic.nix

(limited to 'pkgs/development')

diff --git a/pkgs/development/libraries/science/math/nccl/default.nix b/pkgs/development/libraries/science/math/nccl/default.nix
index c4deccff5b7..1d692f6316f 100644
--- a/pkgs/development/libraries/science/math/nccl/default.nix
+++ b/pkgs/development/libraries/science/math/nccl/default.nix
@@ -1,41 +1,24 @@
-{ stdenv, fetchFromGitHub
-, gcc5, eject, cudatoolkit
-}:
+{ callPackage, cudatoolkit8, cudatoolkit9 }:
 
-stdenv.mkDerivation rec {
-  name = "cudatoolkit-${cudatoolkit.majorVersion}-nccl-${version}";
-  version = "1.3.4-1";
-
-  src = fetchFromGitHub {
-    owner = "NVIDIA";
-    repo = "nccl";
-    rev = "v${version}";
-    sha256 = "0fvnrfn572lc6i2a3xyhbifm53ivcrr46z6cqr3b0bwb1iq79m7q";
+let
+  generic = args: callPackage (import ./generic.nix (removeAttrs args ["cudatoolkit"])) {
+    inherit (args) cudatoolkit;
   };
 
-  nativeBuildInputs = [
-    gcc5
-    eject
-  ];
-
-  propagatedBuildInputs = [
-    cudatoolkit
-  ];
+in
 
-  makeFlags = [
-    "PREFIX=$(out)"
-    "CUDA_HOME=${cudatoolkit}"
-    "CUDA_LIB=${cudatoolkit.lib}/lib"
-  ];
+{
+  nccl_cudatoolkit8 = generic rec {
+    version = "2.1.4";
+    cudatoolkit = cudatoolkit8;
+    srcName = "nccl_${version}-1+cuda${cudatoolkit.majorVersion}_x86_64.txz";
+    sha256 = "1lwwm8kdhna5m318yg304kl2gsz1jwhv4zv4gn8av2m57zh848zi";
+  };
 
-  meta = with stdenv.lib; {
-    description = ''
-      NVIDIA Collective Communications Library.
-      Multi-GPU and multi-node collective communication primitives.
-    '';
-    homepage = https://developer.nvidia.com/nccl;
-    license = licenses.bsd3;
-    platforms = [ "x86_64-linux" ];
-    maintainers = with maintainers; [ hyphon81 ];
+  nccl_cudatoolkit9 = generic rec {
+    version = "2.1.4";
+    cudatoolkit = cudatoolkit9;
+    srcName = "nccl_${version}-1+cuda${cudatoolkit.majorVersion}_x86_64.txz";
+    sha256 = "0pajmqzkacpszs63jh2hw2qqc49kj75kcf7r0ky8hdh560q8xn0p";
   };
 }
diff --git a/pkgs/development/libraries/science/math/nccl/generic.nix b/pkgs/development/libraries/science/math/nccl/generic.nix
new file mode 100644
index 00000000000..aa04d75b078
--- /dev/null
+++ b/pkgs/development/libraries/science/math/nccl/generic.nix
@@ -0,0 +1,57 @@
+{ version
+, srcName
+, sha256
+}:
+
+{ stdenv
+, lib
+, requireFile
+, cudatoolkit
+}:
+
+stdenv.mkDerivation rec {
+  name = "cudatoolkit-${cudatoolkit.majorVersion}-nccl-${version}";
+
+  inherit version;
+
+  src = requireFile rec {
+    name = srcName;
+    inherit sha256;
+    message = ''
+      This nix expression requires that ${name} is already part of the store.
+      Register yourself to NVIDIA Accelerated Computing Developer Program, retrieve the NCCL library
+      at https://developer.nvidia.com/nccl, and run the following command in the download directory:
+      nix-prefetch-url file://${name}
+    '';
+  };
+
+  unpackCmd = "tar xJf $src";
+
+  installPhase = ''
+    function fixRunPath {
+      p=$(patchelf --print-rpath $1)
+      patchelf --set-rpath "$p:${lib.makeLibraryPath [ stdenv.cc.cc ]}" $1
+    }
+    fixRunPath lib/libnccl.so
+
+    mkdir -p $out
+    cp -a include $out/include
+    cp -a lib $out/lib
+  '';
+
+  propagatedBuildInputs = [
+    cudatoolkit
+  ];
+
+  passthru = {
+    inherit cudatoolkit;
+  };
+
+  meta = with stdenv.lib; {
+    description = "Multi-GPU and multi-node collective communication primitives that are performance optimized for NVIDIA GPUs";
+    homepage = https://developer.nvidia.com/nccl;
+    license = licenses.unfree;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ mdaiter ];
+  };
+}
-- 
cgit 1.4.1