From f9d16d59f6351bcc24d2791a325798471f2b3d2e Mon Sep 17 00:00:00 2001
From: José Romildo Malaquias <malaquias@gmail.com>
Date: Fri, 31 Jul 2020 09:25:54 -0300
Subject: enlightenment.enlightenment: move to
 pkgs/desktops/enlightenment/enlightenment/

---
 .../enlightenment/enlightenment/default.nix        | 76 ++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 pkgs/desktops/enlightenment/enlightenment/default.nix

(limited to 'pkgs/desktops/enlightenment/enlightenment/default.nix')

diff --git a/pkgs/desktops/enlightenment/enlightenment/default.nix b/pkgs/desktops/enlightenment/enlightenment/default.nix
new file mode 100644
index 00000000000..90a15a1d523
--- /dev/null
+++ b/pkgs/desktops/enlightenment/enlightenment/default.nix
@@ -0,0 +1,76 @@
+{ stdenv
+, fetchurl
+, meson
+, ninja
+, pkg-config
+, gettext
+, alsaLib
+, acpid
+, bc
+, ddcutil
+, efl
+, pam
+, xkeyboard_config
+, udisks2
+
+, bluetoothSupport ? true, bluez5
+, pulseSupport ? !stdenv.isDarwin, libpulseaudio
+}:
+
+stdenv.mkDerivation rec {
+  pname = "enlightenment";
+  version = "0.24.2";
+
+  src = fetchurl {
+    url = "http://download.enlightenment.org/rel/apps/${pname}/${pname}-${version}.tar.xz";
+    sha256 = "1wfz0rwwsx7c1mkswn4hc9xw1i6bsdirhxiycf7ha2vcipqy465y";
+  };
+
+  nativeBuildInputs = [
+    gettext
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    alsaLib
+    acpid # for systems with ACPI for lid events, AC/Battery plug in/out etc
+    bc # for the Everything module calculator mode
+    ddcutil # specifically libddcutil.so.2 for backlight control
+    efl
+    pam
+    xkeyboard_config
+    udisks2 # for removable storage mounting/unmounting
+  ]
+  ++ stdenv.lib.optional bluetoothSupport bluez5 # for bluetooth configuration and control
+  ++ stdenv.lib.optional pulseSupport libpulseaudio # for proper audio device control and redirection
+  ;
+
+  patches = [
+    # Executables cannot be made setuid in nix store. They should be
+    # wrapped in the enlightenment service module, and the wrapped
+    # executables should be used instead.
+    ./0001-wrapped-setuid-executables.patch
+    ./0003-setuid-missing-path.patch
+  ];
+
+  postPatch = ''
+    substituteInPlace src/modules/everything/evry_plug_calc.c \
+      --replace "ecore_exe_pipe_run(\"bc -l\"" "ecore_exe_pipe_run(\"${bc}/bin/bc -l\""
+  '';
+
+  mesonFlags = [
+    "-D systemdunitdir=lib/systemd/user"
+  ];
+
+  passthru.providedSessions = [ "enlightenment" ];
+
+  meta = with stdenv.lib; {
+    description = "The Compositing Window Manager and Desktop Shell";
+    homepage = "https://www.enlightenment.org";
+    license = licenses.bsd2;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ matejc tstrobel ftrvxmtrx romildo ];
+  };
+}
-- 
cgit 1.4.1