From 2994f14edbf084f7dcba97a972275d31d40afc58 Mon Sep 17 00:00:00 2001
From: taku0 <mxxouy6x3m_github@tatapa.org>
Date: Tue, 4 Apr 2017 23:38:15 +0900
Subject: add source-han-serif-japanese, source-han-serif-korean,
 source-han-serif-simplified-chinese, source-han-serif-traditional-chinese: An
 open source Pan-CJK serif typeface

---
 pkgs/data/fonts/source-han-serif/default.nix | 59 ++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 pkgs/data/fonts/source-han-serif/default.nix

(limited to 'pkgs/data/fonts/source-han-serif')

diff --git a/pkgs/data/fonts/source-han-serif/default.nix b/pkgs/data/fonts/source-han-serif/default.nix
new file mode 100644
index 00000000000..148f5a4538f
--- /dev/null
+++ b/pkgs/data/fonts/source-han-serif/default.nix
@@ -0,0 +1,59 @@
+{stdenv, fetchurl, unzip}:
+
+let
+  makePackage = {variant, language, region, sha256}: stdenv.mkDerivation rec {
+    version = "1.000R";
+    name = "source-han-serif-${variant}-${version}";
+    revision = "f6cf97d92b22e7bd77e355a61fe549ae44b6de76";
+
+    buildInputs = [ unzip ];
+
+    src = fetchurl {
+      url = "https://github.com/adobe-fonts/source-han-serif/raw/${revision}/SubsetOTF/SourceHanSerif${region}.zip";
+      inherit sha256;
+    };
+
+    setSourceRoot = ''
+      sourceRoot=$( echo SourceHanSerif* )
+    '';
+
+    installPhase = ''
+      mkdir -p $out/share/fonts/opentype
+      cp $( find . -name '*.otf' ) $out/share/fonts/opentype
+    '';
+
+    meta = {
+      description = "${language} subset of an open source Pan-CJK serif typeface";
+      homepage = https://github.com/adobe-fonts/source-han-sans;
+      license = stdenv.lib.licenses.ofl;
+      platforms = stdenv.lib.platforms.unix;
+      maintainers = with stdenv.lib.maintainers; [ taku0 ];
+    };
+  };
+in
+{
+  japanese = makePackage {
+    variant = "japanese";
+    language = "Japanese";
+    region = "JP";
+    sha256 = "0488zxr6jpwinzayrznc4ciy8mqcq9afx80xnp37pl9gcxsv0jp7";
+  };
+  korean = makePackage {
+    variant = "korean";
+    language = "Korean";
+    region = "KR";
+    sha256 = "1kwsqrb3s52nminq65n3la540dgvahnhvgwv5h168nrmz881ni9r";
+  };
+  simplified-chinese = makePackage {
+    variant = "simplified-chinese";
+    language = "Simplified Chinese";
+    region = "CN";
+    sha256 = "0y6js0hjgf1i8mf7kzklcl02qg0bi7j8n7j1l4awmkij1ix2yc43";
+  };
+  traditional-chinese = makePackage {
+    variant = "traditional-chinese";
+    language = "Traditional Chinese";
+    region = "TW";
+    sha256 = "0q52dn0vh3pqpr9gn4r4qk99lkvhf2gl12y99n9423brrqyfbi6h";
+  };
+}
-- 
cgit 1.4.1