From 188a413ebc0d89f67cb239255ea97f5d147f3b35 Mon Sep 17 00:00:00 2001
From: Dan Haraj <dan@obsidian.systems>
Date: Mon, 16 Oct 2017 15:56:07 -0400
Subject: sc2-headless: init at 3.17

This packages up the Starcraft II headless Linux client provided by
Blizzard for machine learning research.
---
 .../machine-learning/sc2-headless/default.nix      | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 pkgs/applications/science/machine-learning/sc2-headless/default.nix

(limited to 'pkgs/applications/science/machine-learning')

diff --git a/pkgs/applications/science/machine-learning/sc2-headless/default.nix b/pkgs/applications/science/machine-learning/sc2-headless/default.nix
new file mode 100644
index 00000000000..cf6c3f89920
--- /dev/null
+++ b/pkgs/applications/science/machine-learning/sc2-headless/default.nix
@@ -0,0 +1,53 @@
+{ stdenv
+, lib
+, fetchurl
+, unzip
+, licenseAccepted ? false
+}:
+
+if !licenseAccepted then throw ''
+    You must accept the Blizzard® Starcraft® II AI and Machine Learning License at
+    https://blzdistsc2-a.akamaihd.net/AI_AND_MACHINE_LEARNING_LICENSE.html
+    by setting nixpkgs config option 'sc2-headless.accept_license = true;'
+  ''
+else assert licenseAccepted;
+stdenv.mkDerivation rec {
+  version = "3.17";
+  name = "sc2-headless-${version}";
+
+  src = fetchurl {
+    url = "https://blzdistsc2-a.akamaihd.net/Linux/SC2.${version}.zip";
+    sha256 = "1biyxpf7n95hali1pw30h91rhzrj6sbwrx6s52d00mlnwdhmf2v0";
+  };
+
+  unpackCmd = ''
+    unzip -P 'iagreetotheeula' $curSrc
+  '';
+
+  nativeBuildInputs = [ unzip ];
+
+  installPhase = ''
+    mkdir -p $out
+    cp -r . "$out"
+    rm -r $out/Libs
+  '';
+
+  preFixup = ''
+    find $out -type f -print0 | while IFS=''' read -d ''' -r file; do
+      isELF "$file" || continue
+      patchelf \
+        --interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
+        --set-rpath ${lib.makeLibraryPath [stdenv.cc.cc stdenv.cc.libc]} \
+        "$file"
+    done
+  '';
+
+  meta = {
+    platforms = stdenv.lib.platforms.linux;
+    description = "Starcraft II headless linux client for machine learning research";
+    license = {
+      fullName = "BLIZZARD® STARCRAFT® II AI AND MACHINE LEARNING LICENSE";
+      url = "https://blzdistsc2-a.akamaihd.net/AI_AND_MACHINE_LEARNING_LICENSE.html";
+    };
+  };
+}
-- 
cgit 1.4.1