From 5fef92c4a0c91153e3edac3a61a232581765074a Mon Sep 17 00:00:00 2001
From: Eelco Dolstra <eelco.dolstra@logicblox.com>
Date: Thu, 10 Oct 2013 13:28:21 +0200
Subject: Move pkgs/lib/ to lib/

---
 lib/meta.nix | 48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 lib/meta.nix

(limited to 'lib/meta.nix')

diff --git a/lib/meta.nix b/lib/meta.nix
new file mode 100644
index 00000000000..a5afce9e0cb
--- /dev/null
+++ b/lib/meta.nix
@@ -0,0 +1,48 @@
+/* Some functions for manipulating meta attributes, as well as the
+   name attribute. */
+
+rec {
+
+
+  /* Add to or override the meta attributes of the given
+     derivation.
+
+     Example:
+       addMetaAttrs {description = "Bla blah";} somePkg
+  */
+  addMetaAttrs = newAttrs: drv:
+    drv // { meta = (if drv ? meta then drv.meta else {}) // newAttrs; };
+
+
+  /* Change the symbolic name of a package for presentation purposes
+     (i.e., so that nix-env users can tell them apart).
+  */
+  setName = name: drv: drv // {inherit name;};
+
+
+  /* Like `setName', but takes the previous name as an argument.
+
+     Example:
+       updateName (oldName: oldName + "-experimental") somePkg
+  */
+  updateName = updater: drv: drv // {name = updater (drv.name);};
+
+
+  /* Append a suffix to the name of a package.  !!! the suffix should
+     really be appended *before* the version, at least most of the
+     time.
+  */
+  appendToName = suffix: updateName (name: "${name}-${suffix}");
+
+
+  /* Decrease the nix-env priority of the package, i.e., other
+     versions/variants of the package will be preferred.
+  */
+  lowPrio = drv: addMetaAttrs { priority = "10"; } drv;
+
+  /* Increase the nix-env priority of the package, i.e., this
+     version/variant of the package will be preferred.
+  */
+  hiPrio = drv: addMetaAttrs { priority = "-10"; } drv;
+  
+}
-- 
cgit 1.4.1