From 0b13e8a3413274064ecfbd7d3d66f128912e12c0 Mon Sep 17 00:00:00 2001
From: gnidorah <gnidorah@users.noreply.github.com>
Date: Sat, 6 Oct 2018 21:43:32 +0300
Subject: midisheetmusic: init at 2.6

---
 pkgs/applications/audio/midisheetmusic/default.nix | 60 ++++++++++++++++++++++
 pkgs/top-level/all-packages.nix                    |  2 +
 2 files changed, 62 insertions(+)
 create mode 100644 pkgs/applications/audio/midisheetmusic/default.nix

diff --git a/pkgs/applications/audio/midisheetmusic/default.nix b/pkgs/applications/audio/midisheetmusic/default.nix
new file mode 100644
index 00000000000..26962ad9cc8
--- /dev/null
+++ b/pkgs/applications/audio/midisheetmusic/default.nix
@@ -0,0 +1,60 @@
+{ stdenv, fetchurl
+, mono, dotnetPackages, makeWrapper
+, gtk2, cups, timidity }:
+
+let
+  version = "2.6";
+in stdenv.mkDerivation {
+  name = "midisheetmusic";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/midisheetmusic/MidiSheetMusic-${version}-linux-src.tar.gz";
+    sha256 = "05c6zskj50g29f51lx8fvgzsi3f31z01zj6ssjjrgr7jfs7ak70p";
+  };
+
+  checkInputs = (with dotnetPackages; [ NUnitConsole ]);
+  nativeBuildInputs = [ mono makeWrapper ];
+
+  buildPhase = ''
+    for i in Classes/MidiPlayer.cs Classes/MidiSheetMusic.cs
+    do
+      substituteInPlace $i --replace "/usr/bin/timidity" "${timidity}/bin/timidity"
+    done
+
+    ./build.sh
+  '';
+
+  # include missing file with unit tests for building
+  # switch from mono nunit dll to standalone dll otherwise mono compiler barks
+  # run via nunit3 console, because mono nunit console wants access $HOME
+  checkPhase = ''
+    substituteInPlace UnitTestDLL.csproj \
+      --replace "</Compile>" '</Compile><Compile Include="Classes\UnitTest.cs"/>' \
+      --replace nunit.framework.dll "${dotnetPackages.NUnit}/lib/dotnet/NUnit/nunit.framework.dll"
+    ./build_unit_test.sh
+    nunit3-console bin/Debug/UnitTest.dll
+  '';
+
+  # 2 tests of 47 are still failing
+  doCheck = false;
+
+  installPhase = ''
+    mkdir -p $out/share/applications $out/share/pixmaps $out/bin
+
+    cp deb/midisheetmusic.desktop $out/share/applications
+    cp NotePair.png $out/share/pixmaps/midisheetmusic.png
+    cp bin/Debug/MidiSheetMusic.exe $out/bin/.MidiSheetMusic.exe
+
+    makeWrapper ${mono}/bin/mono $out/bin/midisheetmusic.mono.exe \
+      --prefix LD_LIBRARY_PATH : ${stdenv.lib.makeLibraryPath [ gtk2 cups ]} \
+      --add-flags $out/bin/.MidiSheetMusic.exe
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Convert MIDI Files to Piano Sheet Music for two hands";
+    homepage = http://midisheetmusic.com;
+    license = licenses.gpl2;
+    maintainers = [ maintainers.gnidorah ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index c403077dbb9..b0e68b00cd4 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -4052,6 +4052,8 @@ with pkgs;
 
   mgba = libsForQt5.callPackage ../misc/emulators/mgba { };
 
+  midisheetmusic = callPackage ../applications/audio/midisheetmusic { };
+
   mikutter = callPackage ../applications/networking/instant-messengers/mikutter { };
 
   mimeo = callPackage ../tools/misc/mimeo { };
-- 
cgit 1.4.1