1 files changed, 64 insertions, 0 deletions
diff --git a/pkgs/os-specific/linux/chromium-os/default.nix b/pkgs/os-specific/linux/chromium-os/default.nix
new file mode 100644
index 00000000000..efdf600756f
--- /dev/null
+++ b/pkgs/os-specific/linux/chromium-os/default.nix
@@ -0,0 +1,64 @@
+{ lib, newScope, fetchFromGitiles, symlinkJoin
+, kernelPatches, libqmi, linux_5_4, makeLinuxHeaders, modemmanager
+}:
+
+let
+  self = with self; {
+    callPackage = newScope self;
+
+    upstreamInfo = lib.importJSON ./upstream-info.json;
+
+    chromiumos-overlay = (fetchFromGitiles
+      upstreamInfo.components."src/third_party/chromiumos-overlay") // {
+        passthru.updateScript = ./update.py;
+      };
+
+    common-mk = callPackage ./common-mk { };
+
+    crosvm = callPackage ./crosvm { };
+
+    dbus-properties = callPackage ./dbus-properties { };
+
+    dbus-interfaces = symlinkJoin {
+      name = "dbus-interfaces";
+      paths = [ dbus-properties self.modemmanager modemmanager-next ];
+      passthru.updateScript = ./update.py;
+    };
+
+    libqmi = callPackage ./libqmi {
+      inherit libqmi;
+    };
+
+    linux_5_4 = callPackage ../kernel/linux-cros.nix {
+      kernelPatches =
+        lib.remove kernelPatches.rtl8761b_support linux_5_4.kernelPatches;
+    };
+
+    linux = self.linux_5_4;
+
+    linuxHeaders = (makeLinuxHeaders {
+      inherit (linux) version src patches;
+    });
+
+    minigbm = callPackage ./minigbm { };
+
+    modemmanager = callPackage ./modem-manager {
+      inherit modemmanager;
+    };
+
+    modemmanager-next = callPackage ./modem-manager/next.nix {
+      inherit modemmanager;
+    };
+
+    modp_b64 = callPackage ./modp_b64 { };
+
+    protofiles = callPackage ./protofiles { };
+
+    sommelier = callPackage ./sommelier { };
+
+    vm_protos = callPackage ./vm_protos { };
+  };
+
+in self // (with self; {
+  inherit (upstreamInfo) version;
+})