2 files changed, 46 insertions, 0 deletions
diff --git a/pkgs/desktops/gnome-3/core/gnome-session/default.nix b/pkgs/desktops/gnome-3/core/gnome-session/default.nix
new file mode 100644
index 00000000000..2cd92ce39ca
--- /dev/null
+++ b/pkgs/desktops/gnome-3/core/gnome-session/default.nix
@@ -0,0 +1,36 @@
+{ fetchurl, stdenv, pkgconfig, gnome3, glib, dbus_glib, json_glib, upower
+, libxslt, intltool, makeWrapper, systemd, xorg, epoxy }:
+
+stdenv.mkDerivation rec {
+  inherit (import ./src.nix fetchurl) name src;
+
+  configureFlags = "--enable-systemd";
+
+  buildInputs = with gnome3;
+    [ pkgconfig glib gnome_desktop gtk dbus_glib json_glib libxslt
+      gnome3.gnome_settings_daemon xorg.xtrans gnome3.defaultIconTheme
+      gsettings_desktop_schemas upower intltool gconf makeWrapper systemd
+      epoxy
+    ];
+
+  # FIXME: glib binaries shouldn't be in .dev!
+  preFixup = ''
+    for desktopFile in $(grep -rl "Exec=gnome-session" $out/share)
+    do
+      echo "Patching gnome-session path in: $desktopFile"
+      sed -i "s,^Exec=gnome-session,Exec=$out/bin/gnome-session," $desktopFile
+    done
+    wrapProgram "$out/bin/gnome-session" \
+      --prefix PATH : "${glib.dev}/bin" \
+      --prefix GI_TYPELIB_PATH : "$GI_TYPELIB_PATH" \
+      --suffix XDG_DATA_DIRS : "$out/share:$GSETTINGS_SCHEMAS_PATH" \
+      --suffix XDG_DATA_DIRS : "${gnome3.gnome_shell}/share" \
+      --suffix XDG_CONFIG_DIRS : "${gnome3.gnome_settings_daemon}/etc/xdg"
+  '';
+
+  meta = with stdenv.lib; {
+    platforms = platforms.linux;
+    maintainers = gnome3.maintainers;
+  };
+
+}
diff --git a/pkgs/desktops/gnome-3/core/gnome-session/src.nix b/pkgs/desktops/gnome-3/core/gnome-session/src.nix
new file mode 100644
index 00000000000..d323fea7631
--- /dev/null
+++ b/pkgs/desktops/gnome-3/core/gnome-session/src.nix
@@ -0,0 +1,10 @@
+# Autogenerated by maintainers/scripts/gnome.sh update
+
+fetchurl: {
+  name = "gnome-session-3.24.1";
+
+  src = fetchurl {
+    url = mirror://gnome/sources/gnome-session/3.24/gnome-session-3.24.1.tar.xz;
+    sha256 = "3b4449238e396b95f9616dfd6f99d8345afaf30c7e3cb6a3549f253d9f966eee";
+  };
+}