1 files changed, 64 insertions, 0 deletions
diff --git a/pkgs/by-name/nw/nwg-drawer/package.nix b/pkgs/by-name/nw/nwg-drawer/package.nix
new file mode 100644
index 00000000000..debff8429d8
--- /dev/null
+++ b/pkgs/by-name/nw/nwg-drawer/package.nix
@@ -0,0 +1,64 @@
+{ lib
+, buildGoModule
+, cairo
+, fetchFromGitHub
+, gobject-introspection
+, gtk-layer-shell
+, gtk3
+, pkg-config
+, wrapGAppsHook
+, xdg-utils
+}:
+
+let
+  pname = "nwg-drawer";
+  version = "0.4.1";
+
+  src = fetchFromGitHub {
+    owner = "nwg-piotr";
+    repo = "nwg-drawer";
+    rev = "v${version}";
+    hash = "sha256-2/YI91Rcm+N8tNoKBRIDAQ3T2M6T7+kWngbCzyaXOCc=";
+  };
+
+  vendorHash = "sha256-8s8+ukMQpciQmKt77fNE7r+3cm/UDxO8VtkrNYdKhM8=";
+in
+buildGoModule {
+  inherit pname version src vendorHash;
+
+  nativeBuildInputs = [
+    gobject-introspection
+    pkg-config
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    cairo
+    gtk-layer-shell
+    gtk3
+  ];
+
+  doCheck = false; # Too slow
+
+  preInstall = ''
+    mkdir -p $out/share/nwg-drawer
+    cp -r desktop-directories drawer.css $out/share/nwg-drawer
+  '';
+
+  preFixup = ''
+    # make xdg-open overrideable at runtime
+    gappsWrapperArgs+=(
+      --suffix PATH : ${xdg-utils}/bin
+      --prefix XDG_DATA_DIRS : $out/share
+    )
+  '';
+
+  meta = with lib; {
+    description = "Application drawer for sway Wayland compositor";
+    homepage = "https://github.com/nwg-piotr/nwg-drawer";
+    license = with lib.licenses; [ mit ];
+    mainProgram = "nwg-drawer";
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = with lib.platforms; linux;
+  };
+}