bloomrpc: init at 1.5.3 (#120292)

Co-authored-by: Matheus de Souza Pessanha <matheus_pessanha2001@outlook.com>

1 files changed, 42 insertions, 0 deletions

diff --git a/pkgs/development/web/bloomrpc/default.nix b/pkgs/development/web/bloomrpc/default.nix
new file mode 100644
index 00000000000..94a5c3de37a
--- /dev/null
+++ b/pkgs/development/web/bloomrpc/default.nix
@@ -0,0 +1,42 @@
+{ lib, fetchurl, appimageTools }:
+
+let
+  pname = "bloomrpc";
+  version = "1.5.3";
+
+  src = fetchurl {
+    url = "https://github.com/uw-labs/${pname}/releases/download/${version}/BloomRPC-${version}.AppImage";
+    name = "${pname}-${version}.AppImage";
+    sha512 = "PebdYDpcplPN5y3mRu1mG6CXenYfYvBXNLgIGEr7ZgKnR5pIaOfJNORSNYSdagdGDb/B1sxuKfX4+4f2cqgb6Q==";
+  };
+
+  appimageContents = appimageTools.extractType2 {
+    inherit pname src version;
+  };
+in appimageTools.wrapType2 {
+  inherit pname src version;
+
+  multiPkgs = null; # no 32bit needed
+  extraPkgs = pkgs: appimageTools.defaultFhsEnvArgs.multiPkgs pkgs ++ [ pkgs.bash ];
+
+  extraInstallCommands = ''
+    ln -s $out/bin/${pname}-${version} $out/bin/${pname}
+    install -m 444 -D ${appimageContents}/${pname}.desktop $out/share/applications/${pname}.desktop
+    install -m 444 -D ${appimageContents}/${pname}.png \
+      $out/share/icons/hicolor/512x512/apps/${pname}.png
+    substituteInPlace $out/share/applications/${pname}.desktop \
+      --replace 'Exec=AppRun' 'Exec=${pname}'
+  '';
+
+  meta = with lib; {
+    description = "GUI Client for GRPC Services";
+    longDescription = ''
+      Inspired by Postman and GraphQL Playground BloomRPC aims to provide the simplest
+      and most efficient developer experience for exploring and querying your GRPC services.
+    '';
+    homepage = "https://github.com/uw-labs/bloomrpc";
+    license = licenses.lgpl3Plus;
+    maintainers = with maintainers; [ zoedsoupe ];
+    platforms = [ "x86_64-linux" ];
+  };
+}