cmdliner_1_0: init at 1.0.0

Version 1.0 breaks API and some packages does currently not compile
with it. So it is added as a new package.

1 files changed, 42 insertions, 0 deletions

diff --git a/pkgs/development/ocaml-modules/cmdliner/1.0.nix b/pkgs/development/ocaml-modules/cmdliner/1.0.nix
new file mode 100644
index 00000000000..9448610a378
--- /dev/null
+++ b/pkgs/development/ocaml-modules/cmdliner/1.0.nix
@@ -0,0 +1,42 @@
+{ stdenv, fetchurl, ocaml, findlib, ocamlbuild, opam, topkg, result }:
+
+let
+  pname = "cmdliner";
+in
+
+assert stdenv.lib.versionAtLeast ocaml.version "4.01.0";
+
+stdenv.mkDerivation rec {
+  name = "ocaml-${pname}-${version}";
+  version = "1.0.0";
+
+  src = fetchurl {
+    url = "http://erratique.ch/software/${pname}/releases/${pname}-${version}.tbz";
+    sha256 = "1ryn7qis0izg0wcal8zdlikzzl689l75y6f4zc6blrm93y5agy9x";
+  };
+
+  unpackCmd = "tar xjf $src";
+
+  nativeBuildInputs = [ ocamlbuild opam topkg ];
+  buildInputs = [ ocaml findlib ];
+  propagatedBuildInputs = [ result ];
+
+  createFindlibDestdir = true;
+
+  buildPhase = ''
+    ocaml -I ${findlib}/lib/ocaml/${ocaml.version}/site-lib pkg/pkg.ml build
+  '';
+
+  installPhase = ''
+    opam-installer --script --prefix=$out | sh
+    ln -s $out/lib/${pname} $out/lib/ocaml/${ocaml.version}/site-lib/
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = http://erratique.ch/software/cmdliner;
+    description = "An OCaml module for the declarative definition of command line interfaces";
+    license = licenses.bsd3;
+    platforms = ocaml.meta.platforms or [];
+    maintainers = [ maintainers.vbgl ];
+  };
+}