Merge pull request #18303 from the-kenny/digikam-51

Digikam 5.1

4 files changed, 140 insertions, 0 deletions

diff --git a/pkgs/applications/graphics/digikam/5.1.nix b/pkgs/applications/graphics/digikam/5.1.nix
new file mode 100644
index 00000000000..e0d3ceddca2
--- /dev/null
+++ b/pkgs/applications/graphics/digikam/5.1.nix
@@ -0,0 +1,113 @@
+{ stdenv, fetchurl, cmake, ecm, makeQtWrapper
+
+# For `digitaglinktree`
+, perl, sqlite
+
+, qtbase
+, qtxmlpatterns
+, qtsvg
+, qtwebkit
+
+, kconfigwidgets
+, kcoreaddons
+, kdoctools
+, kfilemetadata
+, knotifications
+, knotifyconfig
+, ktextwidgets
+, kwidgetsaddons
+, kxmlgui
+
+, bison
+, boost
+, eigen
+, exiv2
+, flex
+, jasper
+, lcms2
+, lensfun
+, libgphoto2
+, libkipi
+, liblqr1
+, libusb1
+, marble
+, mysql
+, opencv
+, threadweaver
+
+, oxygen
+}:
+
+stdenv.mkDerivation rec {
+  name    = "digikam-${version}";
+  version = "5.1.0";
+
+  src = fetchurl {
+    url = "http://download.kde.org/stable/digikam/${name}.tar.xz";
+    sha256 = "1w97a5cmg39dgmjgmjwa936gcrmxjms3h2ww61qi1lny84p5x4a7";
+  };
+
+  nativeBuildInputs = [ cmake ecm makeQtWrapper ];
+
+  buildInputs = [
+    qtbase
+    qtxmlpatterns
+    qtsvg
+    qtwebkit
+
+    kconfigwidgets
+    kcoreaddons
+    kdoctools
+    kfilemetadata
+    knotifications
+    knotifyconfig
+    ktextwidgets
+    kwidgetsaddons
+    kxmlgui
+
+    bison
+    boost
+    eigen
+    exiv2
+    flex
+    jasper
+    lcms2
+    lensfun
+    libgphoto2
+    libkipi
+    liblqr1
+    libusb1
+    marble.unwrapped
+    mysql
+    opencv
+    threadweaver
+
+    oxygen
+  ];
+
+  enableParallelBuilding = true;
+
+  cmakeFlags = [
+    "-DLIBUSB_LIBRARIES=${libusb1.out}/lib"
+    "-DLIBUSB_INCLUDE_DIR=${libusb1.dev}/include/libusb-1.0"
+    "-DENABLE_MYSQLSUPPORT=1"
+    "-DENABLE_INTERNALMYSQL=1"
+  ];
+
+  fixupPhase = ''
+    substituteInPlace $out/bin/digitaglinktree \
+      --replace "/usr/bin/perl" "${perl}/bin/perl" \
+      --replace "/usr/bin/sqlite3" "${sqlite}/bin/sqlite3"
+
+    wrapQtProgram $out/bin/digikam
+    wrapQtProgram $out/bin/showfoto
+  '';
+
+  meta = {
+    description = "Photo Management Program";
+    license = stdenv.lib.licenses.gpl2;
+    homepage = http://www.digikam.org;
+    maintainers = with stdenv.lib.maintainers; [ the-kenny ];
+    platforms = stdenv.lib.platforms.linux;
+  };
+}
diff --git a/pkgs/desktops/kde-5/applications/default.nix b/pkgs/desktops/kde-5/applications/default.nix
index 3166b94adaa..980cc9ac25c 100644
--- a/pkgs/desktops/kde-5/applications/default.nix
+++ b/pkgs/desktops/kde-5/applications/default.nix
@@ -57,6 +57,7 @@ let
     libkexiv2 = callPackage ./libkexiv2.nix {};
     libkipi = callPackage ./libkipi.nix {};
     libkomparediff2 = callPackage ./libkomparediff2.nix {};
+    marble = callPackage ./marble.nix {};
     okular = callPackage ./okular.nix {};
     print-manager = callPackage ./print-manager.nix {};
     spectacle = callPackage ./spectacle.nix {};
diff --git a/pkgs/desktops/kde-5/applications/marble.nix b/pkgs/desktops/kde-5/applications/marble.nix
new file mode 100644
index 00000000000..8d6ee5a0f7c
--- /dev/null
+++ b/pkgs/desktops/kde-5/applications/marble.nix
@@ -0,0 +1,24 @@
+{ kdeApp, lib, kdeWrapper
+, ecm, qtscript, qtsvg, qtquickcontrols
+, gpsd
+}:
+
+let
+  unwrapped =
+    kdeApp {
+      name = "marble";
+      meta.license = with lib.licenses; [ lgpl21 gpl3 ];
+
+      nativeBuildInputs = [ ecm ];
+      propagatedBuildInputs = [
+        qtscript qtsvg qtquickcontrols
+        gpsd
+      ];
+
+      enableParallelBuilding = true;
+    };
+in
+kdeWrapper unwrapped {
+  targets = [ "bin/marble-qt" ];
+  paths = [ unwrapped ];
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 6f67c94d5bd..4922b39dad1 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -15788,6 +15788,8 @@ in
 
   dhewm3 = callPackage ../games/dhewm3 {};
 
+  digikam5 = kde5.callPackage ../applications/graphics/digikam/5.1.nix {};
+
   drumkv1 = callPackage ../applications/audio/drumkv1 { };
 
   duckmarines = callPackage ../games/duckmarines { love = love_0_9; };