summary refs log tree commit diff
diff options
context:
space:
mode:
authorP. R. d. O <d.ol.rod@tutanota.com>2022-03-18 22:03:14 -0600
committerP. R. d. O <d.ol.rod@tutanota.com>2022-03-18 22:03:14 -0600
commit14b8c98e78eb77e55fdfa720937fd2d5fbb480e8 (patch)
treefd3f12b6f09e6213f41cf3066fdb59566e973527
parentf055cb1a5883b8b27e37ffb660bc2125aad24976 (diff)
downloadnixpkgs-14b8c98e78eb77e55fdfa720937fd2d5fbb480e8.tar
nixpkgs-14b8c98e78eb77e55fdfa720937fd2d5fbb480e8.tar.gz
nixpkgs-14b8c98e78eb77e55fdfa720937fd2d5fbb480e8.tar.bz2
nixpkgs-14b8c98e78eb77e55fdfa720937fd2d5fbb480e8.tar.lz
nixpkgs-14b8c98e78eb77e55fdfa720937fd2d5fbb480e8.tar.xz
nixpkgs-14b8c98e78eb77e55fdfa720937fd2d5fbb480e8.tar.zst
nixpkgs-14b8c98e78eb77e55fdfa720937fd2d5fbb480e8.zip
rare: init at 1.8.8
-rw-r--r--pkgs/games/rare/default.nix64
-rw-r--r--pkgs/top-level/all-packages.nix2
2 files changed, 66 insertions, 0 deletions
diff --git a/pkgs/games/rare/default.nix b/pkgs/games/rare/default.nix
new file mode 100644
index 00000000000..9bf3aca7542
--- /dev/null
+++ b/pkgs/games/rare/default.nix
@@ -0,0 +1,64 @@
+{ lib, fetchPypi, buildPythonApplication, makeDesktopItem, copyDesktopItems, qt5
+, pillow, psutil, pypresence, pyqt5, python, qtawesome, requests }:
+
+buildPythonApplication rec {
+  pname = "rare";
+  version = "1.8.8";
+
+  src = fetchPypi {
+    inherit version;
+    pname = "Rare";
+    sha256 = "sha256-00CtvBqSrT9yJUHZ5529VrIQtCOYkHRc8+rJHmrTSpg=";
+  };
+
+  nativeBuildInputs = [
+    copyDesktopItems
+    qt5.wrapQtAppsHook
+  ];
+
+  propagatedBuildInputs = [
+    pillow
+    psutil
+    pypresence
+    pyqt5
+    qtawesome
+    requests
+  ];
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = pname;
+      exec = "rare";
+      icon = "Rare";
+      comment = meta.description;
+      desktopName = "Rare";
+      genericName = "Rare (Epic Games Launcher Open Source Alternative)";
+    })
+  ];
+
+  dontWrapQtApps = true;
+
+  preBuild = ''
+    # Solves "PermissionError: [Errno 13] Permission denied: '/homeless-shelter'"
+    export HOME=$(mktemp -d)
+  '';
+
+  postInstall = ''
+    install -Dm644 $out/${python.sitePackages}/rare/resources/images/Rare.png -t $out/share/pixmaps/
+  '';
+
+  preFixup = ''
+    makeWrapperArgs+=("''${qtWrapperArgs[@]}")
+  '';
+
+  # Project has no tests
+  doCheck = false;
+
+  meta = with lib; {
+    description = "GUI for Legendary, an Epic Games Launcher open source alternative";
+    homepage = "https://github.com/Dummerle/Rare";
+    maintainers = with maintainers; [ wolfangaukang ];
+    license = licenses.gpl3Only;
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index d30f5aa539a..2d6d4d210f7 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -3743,6 +3743,8 @@ with pkgs;
 
   psrecord = python3Packages.callPackage ../tools/misc/psrecord {};
 
+  rare = python3Packages.callPackage ../games/rare { };
+
   reg = callPackage ../tools/virtualization/reg { };
 
   river = callPackage ../applications/window-managers/river { };